# Step Function (SFN) root role policy document.
data "aws_iam_policy_document" "sfn_ds_moments_pipeline_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "sfn_ds_moments_pipeline_role" {
  name               = "${var.environment}-${local.sfn_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_ds_moments_pipeline_assume_role_policy.json
}

# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_ds_moments_pipeline_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${local.sfn_name}",
      "arn:aws:logs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:log-group:${var.environment}-${local.sfn_name}:log-stream:*",
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }

  statement {
    effect    = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_role_policy" "sfn_ds_moments_pipeline_log_event_policy_attachment" {
  name   = "${var.environment}-${local.sfn_name}-log-event-policy"
  role   = aws_iam_role.sfn_ds_moments_pipeline_role.id
  policy = data.aws_iam_policy_document.sfn_ds_moments_pipeline_log_event_policy_document.json
}

# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "sfn_ds_moments_pipeline_run_batch_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "batch:SubmitJob",
    ]

    resources = [
      aws_batch_job_definition.read_input_data_job_definition.arn,
      aws_batch_job_definition.fourier_transform_job_definition.arn,
      aws_batch_job_definition.arima_job_definition.arn,
      aws_batch_job_definition.arima_cross_merge_job_definition.arn,
      aws_batch_job_definition.arima_timeseries_merge_job_definition.arn,
      aws_batch_job_definition.clustering_job_definition.arn,
      aws_batch_job_definition.copy_data_to_s3_job_definition.arn,
      aws_batch_job_definition.moments_script_job_definition.arn,
      aws_batch_job_definition.copy_fourier_data_to_s3_job_definition.arn,
      aws_batch_job_queue.batch_compute_environment.arn,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "batch:TerminateJob",
    ]

    resources = [
      aws_batch_job_definition.read_input_data_job_definition.arn,
      aws_batch_job_definition.fourier_transform_job_definition.arn,
      aws_batch_job_definition.arima_job_definition.arn,
      aws_batch_job_definition.arima_cross_merge_job_definition.arn,
      aws_batch_job_definition.arima_timeseries_merge_job_definition.arn,
      aws_batch_job_definition.clustering_job_definition.arn,
      aws_batch_job_definition.copy_data_to_s3_job_definition.arn,
      aws_batch_job_definition.moments_script_job_definition.arn,
      aws_batch_job_definition.copy_fourier_data_to_s3_job_definition.arn,
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "batch:DescribeJobs",
    ]

    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:PutTargets",
      "events:PutRule",
      "events:DescribeRule",
    ]

    resources = [
      "arn:aws:events:${var.aws_region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForBatchJobsRule"
    ]
  }
}

resource "aws_iam_role_policy" "sfn_ds_moments_pipeline_run_batch_role_policy" {
  name   = "${var.environment}-${local.sfn_name}-batch-role-policy"
  role   = aws_iam_role.sfn_ds_moments_pipeline_role.id
  policy = data.aws_iam_policy_document.sfn_ds_moments_pipeline_run_batch_policy_document.json
}

resource "aws_sfn_state_machine" "sfn_ds_moments_pipeline" {
  name       = "${var.environment}-${local.sfn_name}"
  role_arn   = aws_iam_role.sfn_ds_moments_pipeline_role.arn
  definition = local.snf_state_machine_definition

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}

resource "aws_sfn_state_machine" "sfn_ds_moments_single_script_pipeline" {
  name       = "${var.environment}-${local.sfn_name}-single-script"
  role_arn   = aws_iam_role.sfn_ds_moments_pipeline_role.arn
  definition = local.snf_state_machine_single_script_definition

  logging_configuration {
    log_destination        = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level                  = "ALL"
  }

  tracing_configuration {
    enabled = true
  }
}

module "datadog_sfn_dashboard" {
  source             = "git@github.com:theorchard/terraform-datadog.git//modules/step-function?ref=6.18.2"
  environment        = var.environment
  service_name       = local.sfn_name
  application_family = var.application_family
  statemachine_arn   = aws_sfn_state_machine.sfn_ds_moments_pipeline.arn

  failed_execution_message_log_monitor = {
    enabled        = true
    log_group_name = aws_cloudwatch_log_group.sfn_log_group.name
  }
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.escalation_notification_endpoints
}