provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "prod-business-solutions-terraform-state"
    key     = "prod/youtube-audit/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_route53_zone" "zone" {
  name = var.domain_name
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${var.domain_name}"
  statuses = ["ISSUED"]
}

data "aws_wafv2_web_acl" "fargate_service_waf" {
  name  = "${var.environment}-orcd-waf-block"
  scope = "REGIONAL"
}

data "aws_s3_bucket" "access_logs" {
  bucket = "security-${data.aws_caller_identity.current.account_id}-logs"
}

module "youtube_audit_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.1"

  providers = {
    aws.dns = aws
  }

  environment                   = var.environment
  service_name                  = var.service_name
  aws_region                    = var.aws_region
  application_family            = var.application_family
  commit_sha                    = "latest"
  container_port                = "8000"
  task_type                     = "web_service"
  desired_task_count            = 2
  task_cpu                      = 1024
  task_memory                   = 2048
  maximum_capacity              = 4
  minimum_capacity              = 2
  route53_zone_id               = data.aws_route53_zone.zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = "d9a8753d-b7d5-48d0-a78d-8d87d917e45a"

  load_balancer_access_logs_s3_bucket_name = data.aws_s3_bucket.access_logs.bucket
  load_balancer_access_logs_prefix         = "elb/${var.environment}-${var.service_name}"

  https_listener_allow_prefix_list_names = [
    "vpn-ny-users"
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      "AUTH0_DOMAIN" = "auth.prod-youtube-audit.theorchard.io"
    },
    {
      "AUTH0_AUDIENCE" = "https://prod-orch-youtube.us.auth0.com/api/v2/"
    },
    {
      "AUTH0_ISSUER" = "https://auth.prod-youtube-audit.theorchard.io/"
    },
    {
      "AUTH0_ALGORITHMS" = "RS256"
    },
    {
      "CORS_ALLOW_ORIGINS" = local.service_uri
    },
    {
      "AUTH0_REDIRECT_URI" = "${local.service_uri}/callback"
    },
    {
      "HOST" = "0.0.0.0"
    },
  ]

  secrets = [
    {
      "AUTH0_CLIENT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_CLIENT_ID"
    },
    {
      "AUTH0_CLIENT_SECRET" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_CLIENT_SECRET"
    },
    {
      "AUTH0_SPA_CLIENT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_SPA_CLIENT_ID"
    },
    {
      "MYSQL_HOST" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_HOST"
    },
    {
      "MYSQL_DB" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_DATABASE"
    },
    {
      "MYSQL_USER" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_USER"
    },
    {
      "MYSQL_PASSWORD" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_PASSWORD"
    },
    {
      "SNOWFLAKE_PRIVATE_KEY" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_SNOWFLAKE_PRIVATE_KEY"
    },
    {
      "YTCMS_PROJECT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PROJECT_ID"
    },
    {
      "YTCMS_PRIVATE_KEY_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PRIVATE_KEY_ID"
    },
    {
      "YTCMS_PRIVATE" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PRIVATE"
    },
    {
      "YTCMS_CLIENT_EMAIL" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_CLIENT_EMAIL"
    },
    {
      "YTCMS_CLIENT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_CLIENT_ID"
    },
    {
      "SENTRY_DSN" = "${var.environment}/${var.service_name}/SENTRY_DSN"
    },
  ]
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}