module "accounts" {
  source = "git@github.com:theorchard/terraform-aws-accounts-map.git//modules/read_accounts_map?ref=3.1.0"
}

module "business_solutions_automations_build_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets = [
    "${var.environment}/${var.service_name}/SNOWFLAKE_QUERY_SNOWFLAKE_PRIVATE_KEY",
  ]
  action_types = ["read"]

  depends_on = [
    module.lambda_snowflake_query_secrets_manager
  ]
}

resource "aws_iam_policy" "business_solutions_automations_build_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-integration-test-policy"
  policy = module.business_solutions_automations_build_secrets_manager_policy.policy.json
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${module.accounts.orcd_accounts["prod"]}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "business_solutions_automations_build_role" {
  name = "${var.environment}-${var.service_name}-integration-test-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "business_solutions_automations_build_role_policy_attachment" {
  role       = aws_iam_role.business_solutions_automations_build_role.name
  policy_arn = aws_iam_policy.business_solutions_automations_build_secrets_manager_policy.arn
}

module "s3_read_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [{
    bucket = module.publish_client_report_s3_bucket.s3_bucket_name_output
  }]
  action_types = ["read"]
}

resource "aws_iam_policy" "s3_read_policy" {
  name   = "S3-${module.publish_client_report_s3_bucket.s3_bucket_name_output}-RO"
  policy = module.s3_read_policy.policy.json
}

module "s3_read_write_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [{
    bucket = module.publish_client_report_s3_bucket.s3_bucket_name_output
  }]
  action_types = ["read", "write", "delete"]
}

resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${module.publish_client_report_s3_bucket.s3_bucket_name_output}-RW"
  policy = module.s3_read_write_policy.policy.json
}

module "sf_query_results_s3_read_write_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [{
    bucket = module.sf_query_results_s3_bucket.s3_bucket_name_output
  }]
  action_types = ["read", "write", "delete"]
}

resource "aws_iam_policy" "sf_query_results_s3_read_write_policy" {
  name   = "S3-${var.environment}-${module.sf_query_results_s3_bucket.s3_bucket_name_output}-RW"
  policy = module.sf_query_results_s3_read_write_policy.policy.json
}

data "aws_iam_policy_document" "sns_publish" {
  statement {
    effect = "Allow"
    actions = [
      "sns:Publish",
    ]
    resources = [
      module.sns_publishing_client_report_queue.topic_arn
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "sns:ListTopics"
    ]
    resources = [
      "*"
    ]
  }
}

resource "aws_iam_policy" "sns_publish_policy" {
  name   = "SNS-${module.sns_publishing_client_report_queue.topic_name}-publish-policy"
  policy = data.aws_iam_policy_document.sns_publish.json
}

data "aws_iam_policy_document" "business_solutions_snowflake_integration_role_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type        = "AWS"
      identifiers = [
        "arn:aws:iam::494544507972:user/c_orchard_stage_volume",
        "arn:aws:iam::212740118925:user/91n1-s-vast5230",
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values   = [
        "ORCHARD_SFCRole=881_7EyHSe8jZZaQa1tXh+UJx+D0vnk=",
        "DELPHI_SFCRole=2_3kfg10qKYyJwUEVo03tWvCGeTnY=",
      ]
    }
  }
}

resource "aws_iam_role" "business_solutions_snowflake_integration_role" {
  name = "${var.environment}-${var.application_family}-snowflake-integration-role"

  assume_role_policy = data.aws_iam_policy_document.business_solutions_snowflake_integration_role_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "business_solutions_snowflake_integration_role_attachment" {
  policy_arn = aws_iam_policy.sf_query_results_s3_read_write_policy.arn
  role       = aws_iam_role.business_solutions_snowflake_integration_role.name
}

data "aws_iam_policy_document" "allow_invoke_sf_query_lambda_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      module.lambda_snowflake_query.lambda_arn
    ]
  }
}

resource "aws_iam_policy" "allow_invoke_sf_query_lambda_policy" {
  name   = "Lambda-${module.sns_publishing_client_report_queue.topic_name}-invoke-policy"
  policy = data.aws_iam_policy_document.allow_invoke_sf_query_lambda_policy_document.json
}