module "accounts" {
  source = "git@github.com:theorchard/terraform-aws-accounts-map.git//modules/read_accounts_map?ref=3.1.0"
}

module "youtube_audit_build_secrets_manager_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/secretsmanager/secrets_list?ref=0.4.0"

  secrets = [
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_CLIENT_ID",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_CLIENT_SECRET",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_SNOWFLAKE_PRIVATE_KEY",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_CLIENT_EMAIL",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_CLIENT_ID",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PRIVATE",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PRIVATE_KEY_ID",
    "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PROJECT_ID",
  ]
  action_types = ["read"]
}

resource "aws_iam_policy" "youtube_audit_build_secrets_manager_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-integration-test-policy"
  policy = module.youtube_audit_build_secrets_manager_policy.policy.json
}

data "aws_iam_policy_document" "jenkins_assume_role_policy" {
  version = "2012-10-17"
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"
    principals {
      type = "AWS"

      identifiers = [
        "arn:aws:iam::${module.accounts.orcd_accounts["prod"]}:role/prod-jenkins-aws-pipeline-agent",
      ]
    }
  }
}

resource "aws_iam_role" "youtube_audit_build_role" {
  name = "${var.environment}-${var.service_name}-integration-test-role"

  assume_role_policy = data.aws_iam_policy_document.jenkins_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "youtube_audit_build_role_policy_attachment" {
  role       = aws_iam_role.youtube_audit_build_role.name
  policy_arn = aws_iam_policy.youtube_audit_build_secrets_manager_policy.arn
}