module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-business-solutions-terraform-state"
    key     = "qa/youtube-audit/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_route53_zone" "zone" {
  name = var.domain_name
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "services_info" {
  source       = "git@github.com:theorchard/terraform-service-info.git//?ref=1.1.0"
  for_each     = toset(local.external_service_names)
  environment  = "prod"
  service_name = each.value
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${var.domain_name}"
  statuses = ["ISSUED"]
}

data "aws_wafv2_web_acl" "fargate_service_waf" {
  name  = "${var.environment}-orcd-waf-block"
  scope = "REGIONAL"
}

data "aws_s3_bucket" "access_logs" {
  bucket = "security-${data.aws_caller_identity.current.account_id}-logs"
}

module "custom_waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=2.0.2"
  environment       = var.environment
  service_name      = var.service_name
  aws_region        = var.aws_region
  count_waf_enabled = false
  block_waf_enabled = true

  # See https://theorchard.atlassian.net/browse/SYS-25747 for exclusion explanations
  excluded_rules = [
    "SizeRestrictions_BODY",
  ]
}

module "youtube_audit_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.3"

  providers = {
    aws.dns = aws
  }

  environment                   = var.environment
  service_name                  = var.service_name
  aws_region                    = var.aws_region
  application_family            = var.application_family
  commit_sha                    = "latest"
  container_port                = "8000"
  task_type                     = "web_service"
  desired_task_count            = 2
  task_cpu                      = 2048
  task_memory                   = 4096
  maximum_capacity              = 3
  minimum_capacity              = 2
  health_check_interval         = 30
  load_balancer_idle_timeout    = 300
  override_route53_zone_id      = data.aws_route53_zone.zone.zone_id
  vpc_id                        = module.vpc_info.vpc_id
  https_listener_certificate_id = split("/", data.aws_acm_certificate.certificate.arn)[1]
  custom_waf_arn                = module.custom_waf.waf_blocking_arn_output

  load_balancer_access_logs_s3_bucket_name = data.aws_s3_bucket.access_logs.bucket
  load_balancer_access_logs_prefix         = "elb/${var.environment}-${var.service_name}"

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    aws_iam_policy.s3_read_write_policy.arn,
    aws_iam_policy.scheduler_access_policy.arn,
    aws_iam_policy.sqs_access_policy.arn,
  ]

  environment_variables = [
    {
      "AUTH0_DOMAIN" = "auth.qa-youtube-audit.theorchard.io"
    },
    {
      "AUTH0_AUDIENCE" = "https://qa-orch-youtube.us.auth0.com/api/v2/"
    },
    {
      "AUTH0_ISSUER" = "https://auth.qa-youtube-audit.theorchard.io/"
    },
    {
      "AUTH0_ALGORITHMS" = "RS256"
    },
    {
      "SCHEDULER_GROUP_NAME" = aws_scheduler_schedule_group.youtube_audit_schedule_group.name
    },
    {
      "CORS_ALLOW_ORIGINS" = local.service_uri
    },
    {
      "AUTH0_REDIRECT_URI" = "${local.service_uri}/callback"
    },
    {
      "HOST" = "0.0.0.0"
    },
    {
      "SENTRY_DSN" = module.youtube_audit_sentry_project.sentry_key_dsn_public_output
    },
  ]

  secrets = [
    {
      "AUTH0_CLIENT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_CLIENT_ID"
    },
    {
      "AUTH0_CLIENT_SECRET" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_AUTH0_CLIENT_SECRET"
    },
    {
      "MYSQL_HOST" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_HOST"
    },
    {
      "MYSQL_DB" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_DATABASE"
    },
    {
      "MYSQL_USER" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_USER"
    },
    {
      "MYSQL_PASSWORD" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_DB_MYSQL_PASSWORD"
    },
    {
      "SNOWFLAKE_PRIVATE_KEY" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_SNOWFLAKE_PRIVATE_KEY"
    },
    {
      "YTCMS_PROJECT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PROJECT_ID"
    },
    {
      "YTCMS_PRIVATE_KEY_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PRIVATE_KEY_ID"
    },
    {
      "YTCMS_PRIVATE" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_PRIVATE"
    },
    {
      "YTCMS_CLIENT_EMAIL" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_CLIENT_EMAIL"
    },
    {
      "YTCMS_CLIENT_ID" = "${var.environment}/${var.service_name}/YOUTUBE_AUDIT_YTCMS_CLIENT_ID"
    },
  ]
}

module "multiple_secrets_with_same_settings" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 7
}