provider "aws" {
  region = var.region
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/abacus/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "s3_dev_abacus_payments_bucket" {
  source             = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"
  env                = var.environment
  bucket_name        = var.s3_payments_bucket_name
  kms_key_enabled    = false
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "dev_abacus_put_only_bucket_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.s3_dev_abacus_payments_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "dev_abacus_put_only_bucket_policy" {
  name        = "S3-${var.environment}-abacus-buckets-WO"
  description = "Write access to dev abacus bucket(s)"
  policy      = data.aws_iam_policy_document.dev_abacus_put_only_bucket_document.json
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type        = "AWS"
      identifiers = var.additional_browser_assume_role_arns
    }
  }
}

resource "aws_iam_role" "dev_abacus_browser_upload_role" {
  name                 = "${var.environment}-abacus-browser-upload-role"
  max_session_duration = var.bucket_upload_token_duration
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "dev_abacus_payments_browser_upload_policy_attachment" {
  role       = aws_iam_role.dev_abacus_browser_upload_role.id
  policy_arn = aws_iam_policy.dev_abacus_put_only_bucket_policy.arn
}

data "aws_iam_policy_document" "dev_abacus_browser_upload_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    resources = [
      aws_iam_role.dev_abacus_browser_upload_role.arn
    ]
  }
}

resource "aws_iam_policy" "dev_abacus_browser_upload_assume_role_policy" {
  name        = "${var.environment}-abacus-browser-upload-assume-role-policy"
  description = "Assume browser upload role used by the abacus fargate role."
  policy      = data.aws_iam_policy_document.dev_abacus_browser_upload_assume_role_policy_document.json
}