/**
Artist/Track Discovery Frontend Service
**/
provider "aws" {
  region = var.aws_region
}

provider "aws" {
  region  = var.aws_region
  alias   = "dev"
  profile = "dev"
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/artist-similarity-frontend/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.5.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "dev.theorchard.io."
}

# Sentry
module "service_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.0"

  environment                  = var.environment
  application_family           = var.application_family
  platform                     = "python"
  service_name                 = var.service_name
  secrets_manager_service_name = "${var.application_family}/${var.environment}/${var.service_name}"
}

# RDS Instance
module "rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.0.0"

  providers = {
    aws.dns = aws
  }

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "dbadmin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0.mysql_aurora.3.05.2"
  rds_performance_insights_enabled          = false
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"

  custom_kms_key_enabled = false

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

# fargate environment
module "artist_similarity_frontend_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.2.1"

  providers = {
    aws.dns = aws.dev
  }

  environment             = var.environment
  service_name            = var.service_name
  aws_region              = var.aws_region
  desired_task_count      = 1
  minimum_capacity        = 1
  maximum_capacity        = 1
  task_cpu                = 2048
  task_memory             = 4096
  route53_zone_id         = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                  = module.vpc_info.vpc_id
  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids
  application_family      = var.application_family
  blocking_waf_enabled    = true
  health_check_path       = "/"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DB_HOST = module.rds.rds_cluster_endpoint
    },
    {
      DATABASE = module.rds.rds_cluster_database_name
    },
    {
      DB_PORT = module.rds.rds_cluster_port
    }
  ]

  secrets = [
    {
      DB_USERNAME = "${var.environment}/${var.service_name}/username"
    },
    {
      DB_PASSWORD = "${var.environment}/${var.service_name}/password"
    }
  ]
}


# fargate service dashboard
module "artist_similarity_frontend_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.3"

  environment                       = var.environment
  application_family                = var.application_family
  environment_type                  = "fargate"
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  service_name                      = var.service_name
  escalation_notification_endpoints = ""
  notification_endpoints            = ""
}