data "aws_iam_policy_document" "handle_video_asset_lambda_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${data.aws_s3_bucket.raw_asset_bucket.arn}/*"
    ]

    actions = [
      "s3:PutObject"
    ]
  }
}

resource "aws_iam_policy" "handle_video_asset_lambda_policy" {
  name        = "${var.environment}-ddex-ingester-handle-video-asset-lambda-policy"
  description = "handle_video_asset ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.handle_video_asset_lambda_policy_document.json
}

module "lambda_handle_video_asset" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=1.0.5"

  environment              = var.environment
  lambda_name              = "${var.service_name}-handle-video-asset"
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-handle-video-asset-${var.environment}"
  lambda_description       = "Handles an video asset"

  lambda_function_environment_variables = {
    Environment         = var.environment
    LOGGER_DSN          = var.logger_dsn
    SENTRY_DSN          = module.sentry_handle_video_asset_lambda.sentry_key_dsn_public_output
    OA_USER             = var.oa_user
    GRAPHQL_GATEWAY_URL = var.graphql_gateway_url
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_security_group_ids                         = var.vpc_security_group_ids
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.process_tracks_map_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments                 = [
    aws_iam_policy.common_lambda_policy.arn,
    aws_iam_policy.handle_video_asset_lambda_policy.arn
  ]
}