data "aws_iam_policy_document" "send_ingestion_emails" {
  statement {
    effect = "Allow"
    resources = [
      "arn:aws:ses:us-east-1:437795906767:identity/theorchard.com"
    ]
    actions = [
      "ses:SendEmail",
      "ses:SendRawEmail"
    ]
  }
}

resource "aws_iam_policy" "send_ingestion_emails" {
  name        = "SES-${var.environment}-ddex-ingester-report-errors-lambda-policy"
  description = "report_errors ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.send_ingestion_emails.json
}

module "lambda_report_errors" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=1.0.6"

  environment              = var.environment
  lambda_name              = "${var.service_name}-report-errors"
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-report-errors-${var.environment}"
  lambda_description       = "Emails errors to relevant parties"

  lambda_function_environment_variables = {
    Environment         = var.environment
    LOGGER_DSN          = var.logger_dsn
    SENTRY_DSN          = module.sentry_report_errors_lambda.sentry_key_dsn_public_output
    OA_USER             = var.oa_user
    GRAPHQL_GATEWAY_URL = var.graphql_gateway_url
    REPORT_ERRORS_CC    = var.report_errors_cc
    EMAIL_FROM_ADDRESS  = var.email_from_address
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_security_group_ids                         = var.vpc_security_group_ids
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments                 = [
    aws_iam_policy.common_lambda_policy.arn,
    aws_iam_policy.send_ingestion_emails.arn
  ]
}