data "aws_iam_policy_document" "trigger_state_machine_lambda_policy_document" {
  statement {
    actions = [
      "states:StartExecution",
    ]

    resources = [
      aws_sfn_state_machine.sfn_ddex_ingester.arn,
    ]
  }
}

resource "aws_iam_policy" "trigger_state_machine_lambda_policy" {
  name        = "${var.environment}-ddex-ingester-trigger-state-machine-lambda-policy"
  description = "trigger_state_machine ddex-ingester lambda policy"
  policy      = data.aws_iam_policy_document.trigger_state_machine_lambda_policy_document.json
}

# Lambda defintion for 'trigger-state-machine' lambda
module "lambda_trigger_state_machine" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=1.0.8"

  environment              = var.environment
  use_custom_function_name = true
  custom_function_name     = "${var.service_name}-trigger-state-machine-${var.environment}"
  lambda_name              = "${var.service_name}-trigger-state-machine"
  lambda_description       = "Handles triggering the DDEX ingester state machine with appropriate name"

  lambda_function_environment_variables = {
    Environment            = var.environment
    LOGGER_DSN             = var.logger_dsn
    SENTRY_DSN             = module.sentry_trigger_state_machine_lambda.sentry_key_dsn_public_output
    DDEX_STATE_MACHINE_ARN = aws_sfn_state_machine.sfn_ddex_ingester.arn
  }

  lambda_function_timeout                        = var.lambda_default_timeout
  vpc_security_group_ids                         = var.vpc_security_group_ids
  vpc_subnet_ids                                 = var.vpc_subnet_ids
  lambda_function_reserved_concurrent_executions = var.lambda_concurrent_executions
  datadog_enabled                                = var.datadog_enabled
  iam_managed_policy_attachments                 = [
    aws_iam_policy.trigger_state_machine_lambda_policy.arn
  ]
}