# State machine lambda invocation policy
data "aws_iam_policy_document" "invoke_lambda_policy_ddex_ingester" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_parse_ddex.lambda_arn,
      module.lambda_retrieve_orchard_metadata.lambda_arn,
      module.lambda_set_carveouts.lambda_arn,
      module.lambda_handle_artwork.lambda_arn,
      module.lambda_set_pricing.lambda_arn,
      module.lambda_set_main_release_date.lambda_arn,
      module.lambda_handle_audio_asset.lambda_arn,
      module.lambda_send_sme_ack.lambda_arn,
      module.lambda_submit_product.lambda_arn,
      module.lambda_detect_errors.lambda_arn,
      module.lambda_poll_audio_asset_status.lambda_arn,
      module.lambda_poll_artwork_asset_status.lambda_arn,
      module.lambda_report_errors.lambda_arn,
      module.lambda_handle_purged_release.lambda_arn,
      module.lambda_lookup_video_product.lambda_arn,
      module.lambda_handle_video_asset.lambda_arn,
      module.lambda_poll_video_asset_status.lambda_arn
    ]
  }
}

# Step Function (SFN) machine definition template - SME Marketing Ingester
data "template_file" "sfn_ddex_ingester_definition" {
  template = file("${path.module}/${var.sfn_ddex_ingester_definition_file}")
  vars = {
    account_id                           = data.aws_caller_identity.current.account_id,
    region                               = var.region
    environment                          = var.environment
    filename_pattern                     = var.sentinel_file
    lambda_parse_ddex_arn                = module.lambda_parse_ddex.lambda_arn
    lambda_retrieve_orchard_metadata_arn = module.lambda_retrieve_orchard_metadata.lambda_arn
    lambda_set_carveouts_arn             = module.lambda_set_carveouts.lambda_arn
    lambda_handle_artwork_arn            = module.lambda_handle_artwork.lambda_arn
    lambda_set_pricing_arn               = module.lambda_set_pricing.lambda_arn
    lambda_set_main_release_date_arn     = module.lambda_set_main_release_date.lambda_arn
    lambda_handle_audio_asset_arn        = module.lambda_handle_audio_asset.lambda_arn
    lambda_submit_product_arn            = module.lambda_submit_product.lambda_arn
    lambda_send_sme_ack_arn              = module.lambda_send_sme_ack.lambda_arn
    lambda_detect_errors_arn             = module.lambda_detect_errors.lambda_arn
    lambda_poll_audio_asset_status_arn   = module.lambda_poll_audio_asset_status.lambda_arn
    lambda_poll_artwork_asset_status_arn = module.lambda_poll_artwork_asset_status.lambda_arn
    lambda_report_errors_arn             = module.lambda_report_errors.lambda_arn
    lambda_handle_purged_release_arn     = module.lambda_handle_purged_release.lambda_arn
    lambda_lookup_video_product_arn      = module.lambda_lookup_video_product.lambda_arn
    lambda_handle_video_asset_arn        = module.lambda_handle_video_asset.lambda_arn
    lambda_poll_video_asset_status_arn   = module.lambda_poll_video_asset_status.lambda_arn
  }
}

# Step Function (SFN) root role - Role creation using policy definition
resource "aws_iam_role" "sfn_ddex_ingester_role" {
  name               = "${var.environment}-ddex-ingester-sfn-role"
  description        = "Governing role for ${var.environment}-ddex-ingester-sfn execution and resource access."
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_statemachines_role.json
}

# Policy that gives the state machine role permission to invoke lambdas
resource "aws_iam_role_policy" "sfn_ddex_ingester_invoke_lambda_role_policy" {
  name   = "${var.environment}-ddex-ingester-lambda-role-policy"
  role   = aws_iam_role.sfn_ddex_ingester_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_ddex_ingester.json
}

# Step Function (SFN) - SFN LogEvent - Policy creation using policy definition document
resource "aws_iam_policy" "sfn_ddex_ingester_log_event_policy" {
  name        = "${var.environment}-ddex-ingester-sfn-logevent-policy"
  description = "Shared SFN LogEvent Policy for DDEX ingester sfn services."
  policy      = data.aws_iam_policy_document.ddex_ingester_log_event_policy_document.json
}

# Attach Step Function (SFN) LogEvent Policy to various root roles sme-marketing-ingester
resource "aws_iam_role_policy_attachment" "sfn_ddex_ingester_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_ddex_ingester_role.name
  policy_arn = aws_iam_policy.sfn_ddex_ingester_log_event_policy.arn
}

# Step Function (SFN) definition for marketing ingest
resource "aws_sfn_state_machine" "sfn_ddex_ingester" {
  name       = "${var.environment}-ddex-ingester-sfn"
  role_arn   = aws_iam_role.sfn_ddex_ingester_role.arn
  definition = data.template_file.sfn_ddex_ingester_definition.rendered
}