# State machine lambda invocation policy
data "aws_iam_policy_document" "invoke_lambda_policy_sme_marketing_ingester" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_parse_sme_marketing.lambda_arn,
      module.lambda_lookup_orchard_product.lambda_arn,
      module.lambda_import_store_links.lambda_arn,
      module.lambda_import_delivery_history.lambda_arn
    ]
  }
}

# Step Function (SFN) machine definition template - SME Marketing Ingester
data "template_file" "sfn_sme_marketing_ingester_definition" {
  template = file("${path.module}/${var.sfn_sme_marketing_definition_file}")
  vars = {
    account_id                         = data.aws_caller_identity.current.account_id,
    region                             = var.region
    environment                        = var.environment
    lambda_parse_sme_marketing_arn     = module.lambda_parse_sme_marketing.lambda_arn
    lambda_lookup_orchard_product_arn  = module.lambda_lookup_orchard_product.lambda_arn
    lambda_import_store_links_arn      = module.lambda_import_store_links.lambda_arn
    lambda_import_delivery_history_arn = module.lambda_import_delivery_history.lambda_arn
  }
}

# Step Function (SFN) root role - Role creation using policy definition
resource "aws_iam_role" "sfn_sme_marketing_ingester_role" {
  name               = "${var.environment}-sme_marketing-sfn-role"
  description        = "Governing role for ${var.environment}-sme_marketing-sfn execution and resource access."
  assume_role_policy = data.aws_iam_policy_document.sfn_assume_statemachines_role.json
}

# Policy that gives the state machine role permission to invoke lambdas
resource "aws_iam_role_policy" "sfn_sme_marketing_invoke_lambda_role_policy" {
  name   = "${var.environment}-ddex-ingester-lambda-role-policy"
  role   = aws_iam_role.sfn_sme_marketing_ingester_role.id
  policy = data.aws_iam_policy_document.invoke_lambda_policy_sme_marketing_ingester.json
}

# Step Function (SFN) - SFN LogEvent - Policy creation using policy definition document
resource "aws_iam_policy" "sfn_sme_marketing_ingester_log_event_policy" {
  name        = "sfn-${var.environment}-sme-marketing-sfn-logevent-policy"
  description = "Shared SFN LogEvent Policy for sme-marketing sfn services."
  policy      = data.aws_iam_policy_document.ddex_ingester_log_event_policy_document.json
}

# Attach Step Function (SFN) LogEvent Policy to various root roles sme-marketing-ingester
resource "aws_iam_role_policy_attachment" "sfn_sme_marketing_ingester_log_event_policy_attachment" {
  role       = aws_iam_role.sfn_sme_marketing_ingester_role.name
  policy_arn = aws_iam_policy.sfn_sme_marketing_ingester_log_event_policy.arn
}

# Step Function (SFN) definition for marketing ingest
resource "aws_sfn_state_machine" "sfn_sme_marketing_ingester" {
  name       = "${var.environment}-sme-marketing-ingester-sfn"
  role_arn   = aws_iam_role.sfn_sme_marketing_ingester_role.arn
  definition = data.template_file.sfn_sme_marketing_ingester_definition.rendered
}