# State Function defintion for GDA score Calculation flow.


# Step Function (SFN) root role policy document.
data "aws_iam_policy_document" "sfn_gda_score_calculation_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
        "events.amazonaws.com",
      ]
    }
  }
}
# create iam role
resource "aws_iam_role" "sfn_gda_score_calculation_assume_role" {
  name               = "${var.environment}-workflow-${var.service_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_gda_score_calculation_assume_role.json
}


# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_gda_score_calculation_log_event_policy_document" {
  statement {
    effect    = "Allow"
    resources = ["*"]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }
}
resource "aws_iam_role_policy" "sfn_gda_score_calculation_log_event_policy_attachment" {
  name   = "${var.environment}-${var.service_name}-log-event-policy"
  role   = aws_iam_role.sfn_gda_score_calculation_assume_role.id
  policy = data.aws_iam_policy_document.sfn_gda_score_calculation_log_event_policy_document.json
}


# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "sfn_gda_score_calculation_invoke_lambda_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_gda_knowledge_graph.lambda_arn,
      module.lambda_gda_spotify_scraper.lambda_arn,
      module.lambda_gda_tiktok_scraper.lambda_arn,
      module.lambda_gda_youtube_scraper.lambda_arn,
      module.lambda_gda_calculate_score.lambda_arn,
    ]

  }
}

# attach invoke lambda policy.
resource "aws_iam_role_policy" "sfn_gda_score_calculation_invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.service_name}-lambda-role-policy"
  role   = aws_iam_role.sfn_gda_score_calculation_assume_role.id
  policy = data.aws_iam_policy_document.sfn_gda_score_calculation_invoke_lambda_policy_document.json
}


data "aws_iam_policy_document" "sfn_gda_score_calculation_xray_policy_document" {
  statement {
    effect    = "Allow"
    resources = ["*"]

    actions = [
      "xray:PutTraceSegments",
      "xray:PutTelemetryRecords",
      "xray:GetSamplingRules",
      "xray:GetSamplingTargets"
    ]
  }
}

# attach invoke xray policy.
resource "aws_iam_role_policy" "sfn_gda_score_calculation_xray_role_policy" {
  name   = "${var.environment}-${var.service_name}-xray-role-policy"
  role   = aws_iam_role.sfn_gda_score_calculation_assume_role.id
  policy = data.aws_iam_policy_document.sfn_gda_score_calculation_xray_policy_document.json
}

# Template for state machine.
data "template_file" "gda_score_calculation_definition" {
  template = file("${path.module}/gda_score_calculation.json")
  # all vars that are used in the json file.
  vars = {
    environment                          = var.environment
    lambda_gda_knowledge_graph           = module.lambda_gda_knowledge_graph.lambda_arn
    lambda_gda_spotify_scraper           = module.lambda_gda_spotify_scraper.lambda_arn
    lambda_gda_tiktok_scraper            = module.lambda_gda_tiktok_scraper.lambda_arn
    lambda_gda_youtube_scraper           = module.lambda_gda_youtube_scraper.lambda_arn
    lambda_gda_calculate_score           = module.lambda_gda_calculate_score.lambda_arn
    lambda_gda_default_timeout           = var.lambda_default_timeout
    lambda_gda_retry_attempts            = var.lambda_default_retry_attempts
    lambda_gda_scraping_function_timeout = var.lambda_scraping_function_timeout
  }
}


resource "aws_sfn_state_machine" "gda_score_calculation" {
  name       = "${var.environment}-workflow-${var.service_name}"
  role_arn   = aws_iam_role.sfn_gda_score_calculation_assume_role.arn
  definition = data.template_file.gda_score_calculation_definition.rendered
  tracing_configuration {
    enabled = true
  }
}