# Secrets Manager for sqs consumer
module "consumer_secrets" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.consumer_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = "${var.service_name}-consumer"
  secret_name        = each.value
}

# IAM Policy Document for consumer lambda to read GitHub token
data "aws_iam_policy_document" "consumer_secrets_policy" {
  statement {
    effect = "Allow"
    actions = [
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret"
    ]
    resources = [
      for secret in module.consumer_secrets : secret.secret_arn
    ]
  }
}

# IAM Policy for consumer lambda to read secret
resource "aws_iam_policy" "consumer_secrets_policy" {
  name   = "SecretsManager-${var.environment}-${var.service_name}-consumer"
  policy = data.aws_iam_policy_document.consumer_secrets_policy.json
}

# Main Lambda Function for webhook processing (SQS consumer)
module "lambda_jira_webhook" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment                                    = var.environment
  lambda_function_timeout                        = 300
  use_container_image                            = true
  lambda_description                             = "SQS consumer for Jira webhook messages - processes and creates GitHub issues"
  lambda_name                                    = "${var.service_name}-consumer"
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  application_family                             = var.application_family
  lambda_function_memory_size                    = 1024
  lambda_function_reserved_concurrent_executions = 25

  # SQS Event Source Mapping
  sqs_event_enabled                 = true
  event_source_mapping_queue_name   = module.jira_webhook_queue.queue_name
  event_source_mapping_region       = var.aws_region
  event_source_mapping_batch_size   = 1
  event_source_mapping_batch_window = 0

  iam_managed_policy_attachments = [
    aws_iam_policy.consumer_secrets_policy.arn
  ]

  lambda_function_environment_variables = {
    Environment = var.environment
  }
}

# SQS Queue for Jira webhook messages
module "jira_webhook_queue" {
  source = "git@github.com:theorchard/terraform-sqs.git//?ref=2.4.1"

  environment        = var.environment
  application_family = var.application_family
  queue_name         = var.service_name

  sqs_max_message_size           = 256 * 1024  # 256 KB
  sqs_message_retention_seconds  = 14 * 24 * 60 * 60  # 14 days
  sqs_visibility_timeout_seconds = 5 * 60  # 5 minutes

  sqs_deadletter_enabled               = "true"
  deadletter_max_message_size          = 256 * 1024
  deadletter_message_retention_seconds = 14 * 24 * 60 * 60
}