provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/kafka-infra/gsheets_source/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

resource "aws_ecr_repository" "kafka_connect_gsheets_source_repository" {
  name = "${var.service_name}-gsheets-source"

  encryption_configuration {
    encryption_type = "AES256"
  }
}

module "kafka_gsheets_source_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=1.7.4"

  environment                       = var.environment
  service_name                      = "${var.service_name}-gsheets-source"
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 1
  task_cpu                          = 1024
  task_memory                       = 2048
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${var.connector_name}"
  web_service_health_check_command  = "[ \"$(curl -s -f http://localhost:8083/connectors/${var.connector_name}/tasks/0/status | jq -r .state)\" == 'RUNNING' ] || exit 1"
  vpc_id                            = "vpc-34dbfd51"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SERVICE_NAME = "${var.service_name}-gsheets-source"
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      KAFKA_TOPICS = var.kafka_topics
    },
    {
      KAFKA_CONNECTOR_NAME = var.connector_name
    },
    {
      CONNECTOR_LOG_LEVEL = "OFF"
    },
    {
      CONNECTOR_CLASS = "org.apache.camel.kafkaconnector.googlesheetsstream.CamelGooglesheetsstreamSourceConnector"
    },
    {
      CONNECT_KEY_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      CONNECT_VALUE_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      CONNECT_SCHEMAS_ENABLE = var.connect_schemas_enable
    },
    {
      GCP_APP_NAME = var.gcp_app_name
    },
    {
      SPREADSHEET_ID = var.spreadsheet_id
    },
    {
      SPREADSHEET_RANGE = var.spreadsheet_range
    },
    {
      SPREADSHEET_READ_DIMENSION = var.spreadsheet_read_dimension
    },
    {
      AWS_SECRETS_MANAGER_KEY = "${var.environment}/${var.service_name}-gsheets-source/google_api_credentials"
    },
    {
      DEBUG_MODE = "False"
    }
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_gsheets_source_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}