provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/kafka-infra/neo4j-sink/chartmetric-charts/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "kafka_neo_sink_cmc_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=2.3.1"

  environment                       = var.environment
  application_family                = var.application_family
  service_name                      = "${var.service_name}-neo-sink-cmc"
  non_ecr_image                     = "${data.aws_caller_identity.current.account_id}.dkr.ecr.${var.aws_region}.amazonaws.com/${var.service_name}-neo-sink:latest"
  aws_region                        = var.aws_region
  service_platform_version          = "1.4.0"
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 1
  task_cpu                          = 1024
  task_memory                       = 2048
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${var.connector_name}"
  web_service_health_check_command  = "[ \"$(curl -s -f http://localhost:8083/connectors/${var.connector_name}/tasks/0/status | jq -r .state)\" == 'RUNNING' ] || exit 1"
  vpc_id                            = "vpc-34dbfd51"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      CONNECT_GROUP_UNIQUE_IDENTIFIER = "${var.environment}-${var.service_name}-neo-sink-cmc"
    },
    {
      SERVICE_NAME = "${var.service_name}-neo-sink-cmc"
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = var.connect_bootstrap_servers
    },
    {
      NEO4J_SERVER_URI = "neo4j+s://${var.environment}-neo4j-cluster.%{if var.environment == "dev"}${"dev."}%{ else }${""}%{ endif }theorchard.io:7687"
    },
    {
      NEO4J_KEY_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      NEO4J_VALUE_CONVERTER = "org.apache.kafka.connect.json.JsonConverter"
    },
    {
      MAX_TASKS = "1"
    },
    {
      NEO4J_KEY_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_VALUE_CONVERTER_SCHEMAS_ENABLE = "false"
    },
    {
      NEO4J_BATCH_SIZE = "2500"
    },
    {
      KAFKA_MAX_POLL_RECORDS = "2500"
    },
    {
      NEO4J_BATCH_EXEC_TIMEOUT = "30000"
    },
    {
      NEO4J_RETRY_MAX_ATTEMPTS = "25"
    },
    {
      NEO4J_RETRY_BACKOFF_TIMEOUT = "100"
    },
    {
      NEO4J_QUERY_PARALLELIZE = "false"
    },
    {
      KAFKA_TOPICS = join(",", [
        "etl.chartmetric.charts.globalsoundrecording.relations",
        "etl.chartmetric.charts.soundrecording.noisrc.nodes",
        "etl.chartmetric.charts.amazon.trackandparticipant.relations",
        "etl.chartmetric.charts.applemusic.trackandparticipant.relations",
        "etl.chartmetric.charts.deezer.trackandparticipant.relations",
        "etl.chartmetric.charts.itunes.trackandparticipant.relations",
        "etl.chartmetric.charts.linemusic.trackandparticipant.relations",
        "etl.chartmetric.charts.recochoku.trackandparticipant.relations",
        "etl.chartmetric.charts.shazam.trackandparticipant.relations",
        "etl.chartmetric.charts.soundcloud.trackandparticipant.relations",
        "etl.chartmetric.charts.spotify.trackandparticipant.relations",
        "etl.chartmetric.charts.tiktok.trackandparticipant.relations",
        "etl.chartmetric.charts.youtube.trackandparticipant.relations",
        "etl.chartmetric.charts.amazon.productandlabel.relations",
        "etl.chartmetric.charts.applemusic.productandlabel.relations",
        "etl.chartmetric.charts.deezer.productandlabel.relations",
        "etl.chartmetric.charts.itunes.productandlabel.relations",
        "etl.chartmetric.charts.shazam.productandlabel.relations",
        "etl.chartmetric.charts.spotify.productandlabel.relations",
      ])
    },
    {
      AWS_SECRETS_MANAGER = "true"
    },
    {
      AWS_REGION = var.aws_region
    },
    {
      DLQ_TOPIC_NAME = "dlq.chartmetric.charts.neo4jsink.status"
    },
    {
      DEBUG_MODE = "false"
    },
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "allow_intra_cluster_communication_cmc" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_neo_sink_cmc_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}