# Lambda definition for FingerprintAudio step

locals {
  fingerprint_lambda_name = "${var.lambda_name_prefix}-${var.service_name}-fingerprint"
}

data "aws_s3_bucket" "s3_audio_bucket" {
  bucket = var.s3_audio_bucket
}

data "aws_iam_policy_document" "s3_audio_readonly_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject"
    ]

    resources = [
      "${data.aws_s3_bucket.s3_audio_bucket.arn}/${var.s3_audio_key_prefix}/*",
    ]
  }
}

resource "aws_iam_policy" "s3_audio_readonly_policy" {
  name   = "S3-${data.aws_s3_bucket.s3_audio_bucket.id}-${var.s3_audio_key_prefix}-RO"
  policy = data.aws_iam_policy_document.s3_audio_readonly_policy_document.json
}

module "lambda_content_match_audio_fingerprint" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=2.4.5"

  environment                            = var.environment
  application_family                     = var.application_family
  lambda_name                            = local.fingerprint_lambda_name
  lambda_description                     = "Fingerprint audio files."
  vpc_id                                 = var.vpc_id
  vpc_subnet_ids                         = var.vpc_subnet_ids
  use_container_image                    = true
  datadog_advanced_enabled               = true
  lambda_function_ephemeral_storage_size = 10240
  lambda_function_memory_size            = 10240
  lambda_function_timeout                = 300

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.s3_audio_readonly_policy.arn
  ]
}