provider "aws" {
  region = var.aws_region
}

data "aws_caller_identity" "current" {}

data "aws_lambda_function" "datadog_lambda_function" {
  function_name = "DatadogLambdaFunction"
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/lambda-metadata-consistency/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "lambda_test_mcc" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.6"
  lambda_name        = var.test_mcc_lambda_name
  lambda_description = "Lambda Test for SFN + Fargate"
  environment        = var.environment
  application_family = var.application_family
  use_container_image = true

  dlq_enabled              = false
  cloudwatch_event_enabled = false

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
  }
}

data "aws_iam_policy_document" "assume_role_for_sfn_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
        "scheduler.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "test_mcc_sfn_role" {
  name               = "${var.environment}-test-mcc-sfn-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_sfn_state_machine_policy.json
}

data "aws_iam_policy_document" "invoke_test_lambdas_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_test_mcc.lambda_arn
    ]
    effect = "Allow"
  }
}

resource "aws_iam_policy" "invoke_test_lambdas_policy" {
    name = "Lambda-${var.environment}-test-mcc-invoke-policy"
    policy = data.aws_iam_policy_document.invoke_test_lambdas_policy_document.json
}

resource "aws_iam_role_policy_attachment" "invoke_test_lambdas_role_policy_attachment" {
    role        = aws_iam_role.test_mcc_sfn_role.name
    policy_arn  = aws_iam_policy.invoke_test_lambdas_policy.arn
}

# Step Function cloudwatch logs permission policy
data "aws_iam_policy_document" "cloudwatch_log_event_policy_document" {
  statement {
    effect = "Allow"
    resources = [
      "${aws_cloudwatch_log_group.sfn_log_group.arn}:*",
    ]
    actions = [
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }

  statement {
    effect = "Allow"
    resources = ["*"]
    actions = [
      "logs:CreateLogDelivery",
      "logs:DeleteLogDelivery",
      "logs:DescribeLogGroups",
      "logs:DescribeResourcePolicies",
      "logs:GetLogDelivery",
      "logs:ListLogDeliveries",
      "logs:PutResourcePolicy",
      "logs:UpdateLogDelivery",
    ]
  }
}

resource "aws_iam_policy" "sfn_log_event_policy" {
  name = "${var.environment}-${var.service_name}-sfn-log-policy"
  description = "${var.environment}-${var.service_name}-sfn-log-policy"
  policy = data.aws_iam_policy_document.cloudwatch_log_event_policy_document.json
}

resource "aws_iam_role_policy_attachment" "sfn_log_event_policy_attachment" {
  role       = aws_iam_role.test_mcc_sfn_role.name
  policy_arn = aws_iam_policy.sfn_log_event_policy.arn
}

resource "aws_cloudwatch_log_group" "sfn_log_group" {
  name = "${var.environment}-${var.service_name}-sfn-log-group"
  retention_in_days = 365
  tags = local.tags
}

resource "aws_cloudwatch_log_subscription_filter" "datadog_lambda_log_filter" {
  name = "${var.environment}-${var.service_name}-sfn-log-group-subscription-filter"
  log_group_name = aws_cloudwatch_log_group.sfn_log_group.name
  filter_pattern = ""
  destination_arn = data.aws_lambda_function.datadog_lambda_function.arn
  distribution = "ByLogStream"
}

data "template_file" "test_mcc_state_machine_def" {
  template = file("${path.module}/test_mcc_sfn.json")

  vars = {
    test_lambda_arn = module.lambda_test_mcc.lambda_arn
  }
}

resource "aws_sfn_state_machine" "test_mcc_state_machine" {
  name = "${var.environment}-test_mcc_sfn"
  role_arn = aws_iam_role.test_mcc_sfn_role.arn
  definition = data.template_file.test_mcc_state_machine_def.rendered

  tags = local.tags

  logging_configuration {
    log_destination = "${aws_cloudwatch_log_group.sfn_log_group.arn}:*"
    include_execution_data = true
    level = "ERROR"
  }

  tracing_configuration {
    enabled = true
  }
}