# State Function defintion for Populate Hfa Pending Request flow.

# Step Function (SFN) root role policy document.
data "aws_iam_policy_document" "sfn_populate_hfa_pending_request_assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type = "Service"
      identifiers = [
        "states.amazonaws.com",
        "lambda.amazonaws.com",
        "events.amazonaws.com",
      ]
    }
  }
}

# create iam role
resource "aws_iam_role" "sfn_populate_hfa_pending_request_assume_role" {
  name               = "${var.environment}-${var.service_name}-state-machine-role"
  assume_role_policy = data.aws_iam_policy_document.sfn_populate_hfa_pending_request_assume_role.json
}


# Step Function (SFN) - SFN Cloudwatch logs permission policy
data "aws_iam_policy_document" "sfn_populate_hfa_pending_request_log_event_policy_document" {
  statement {
    effect    = "Allow"
    resources = ["*"]

    actions = [
      "logs:CreateLogGroup",
      "logs:CreateLogStream",
      "logs:PutLogEvents"
    ]
  }
}

resource "aws_iam_role_policy" "sfn_populate_hfa_pending_request_log_event_policy_attachment" {
  name   = "${var.environment}-${var.service_name}-log-event-policy"
  role   = aws_iam_role.sfn_populate_hfa_pending_request_assume_role.id
  policy = data.aws_iam_policy_document.sfn_populate_hfa_pending_request_log_event_policy_document.json
}


# State machine lambda policy that gives the state machine role permission to invoke lambdas
data "aws_iam_policy_document" "sfn_populate_hfa_pending_request_lambda_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_populate_hfa_pending_request.lambda_arn,
    ]

  }
}

# attach invoke lambda policy.
resource "aws_iam_role_policy" "populate_hfa_pending_request_invoke_lambda_role_policy" {
  name   = "${var.environment}-${var.service_name}-lambda-role-policy"
  role   = aws_iam_role.sfn_populate_hfa_pending_request_assume_role.id
  policy = data.aws_iam_policy_document.sfn_populate_hfa_pending_request_lambda_policy_document.json
}

# Template for state machine.
data "template_file" "populate_hfa_pending_request_definition" {
  template = file("${path.module}/populate_hfa_pending_request.json")
  # all vars that are used in the json file.
  vars = {
    environment                          = var.environment
    populate_hfa_pending_request_lambda_arn           = module.lambda_populate_hfa_pending_request.lambda_arn
  }
}

resource "aws_sfn_state_machine" "populate_hfa_pending_request" {
  name       = "${var.environment}-${var.service_name}"
  role_arn   = aws_iam_role.sfn_populate_hfa_pending_request_assume_role.arn
  definition = data.template_file.populate_hfa_pending_request_definition.rendered
  tracing_configuration {
    enabled = true
  }
}