locals {
  lambda_trigger_product_update = "lambda-${var.service_name}-trigger-product-update"
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/lambda-timed-release/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

provider "aws" {
  region = var.aws_region
}

# create eventbridge scheduler group
resource "aws_scheduler_schedule_group" "product_update_schedules" {
  name = "${var.environment}-${var.service_name}-product-update-schedules"
}

# create scheduler execution policy
data "aws_iam_policy_document" "scheduler_execution_policy_document" {
  statement {
    effect = "Allow"

    principals {
      type        = "Service"
      identifiers = [
        "scheduler.amazonaws.com",
      ]
    }

    actions = ["sts:AssumeRole"]
  }
}

# create scheduler execution role
resource "aws_iam_role" "lambda_timed_release_scheduling_role" {
  name               = "${var.environment}-lambda-timed-release-scheduling-role"
  assume_role_policy = data.aws_iam_policy_document.scheduler_execution_policy_document.json
}

# create invoke lambda policy
data "aws_iam_policy_document" "timed_release_invoke_lambda_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "lambda:InvokeFunction",
    ]
    resources = [
      module.lambda_trigger_product_update.lambda_arn
    ]
  }
}

# attach invoke lambda policy.
resource "aws_iam_role_policy" "timed_release_invoke_lambda_role_policy" {
  name   = "${var.environment}-timed-release-invoke-lambda-role-policy"
  role   = aws_iam_role.lambda_timed_release_scheduling_role.id
  policy = data.aws_iam_policy_document.timed_release_invoke_lambda_policy_document.json
}

module "lambda_trigger_product_update" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=2.8.0"

  environment               = var.environment
  application_family        = var.application_family
  lambda_name               = local.lambda_trigger_product_update

  lambda_description        = "Trigger the product update flow"
  lambda_function_timeout   = "300"
  use_container_image       = true
  vpc_enabled               = true
  vpc_subnet_ids            = var.vpc_subnet_ids

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
  }
}