module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "dev"
  profile = "dev"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/nr-sfn-fargate-poc/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.1.0"

  environment = var.environment
}


data "aws_iam_policy" "s3_test_orcd_bucket_RW" {
  name = "s3-test-orcd-bucket-RW"
}


module "lambda_nr_sfn_fargate_poc_create" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"
  lambda_name        = var.create_lambda
  lambda_description = "Lambda Test for SFN + Fargate"
  environment        = var.environment
  application_family = var.application_family

  dlq_enabled              = false
  cloudwatch_event_enabled = false

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
  }
}

module "lambda_nr_sfn_fargate_poc_metadata" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"
  lambda_name        = var.metadata_lambda
  lambda_description = "Lambda Test for SFN + Fargate"
  environment        = var.environment
  application_family = var.application_family

  dlq_enabled              = false
  cloudwatch_event_enabled = false

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
  }
}

module "lambda_nr_sfn_fargate_poc_combiner" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.5"
  lambda_name        = var.combiner_lambda
  lambda_description = "Lambda Test for SFN + Fargate"
  environment        = var.environment
  application_family = var.application_family

  dlq_enabled              = false
  cloudwatch_event_enabled = false

  lambda_function_environment_variables = {
    ENVIRONMENT = var.environment
  }
}

module "nr_sfn_fargate_poc" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.0.1"

  providers = {
    aws.dns = aws.dev
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  desired_task_count = 0
  minimum_capacity   = 0
  maximum_capacity   = 0

  vpc_id                  = module.vpc_info.vpc_id
  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids

  health_check_path = "/health/"

  environment_variables = [
    {
      Environment = var.environment
    }
  ]

  iam_managed_policy_attachments = [
    data.aws_iam_policy.s3_test_orcd_bucket_RW.arn
  ]
}



data "aws_iam_policy_document" "assume_role_for_sfn_state_machine_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "Service"

      identifiers = [
        "states.${var.aws_region}.amazonaws.com",
      ]
    }
  }
}

resource "aws_iam_role" "invoke_poc_lambdas_fargate_from_state_machine" {
  name               = "${var.environment}-nr-sfn-fargate-poc-invoke-lambdas-role"
  assume_role_policy = data.aws_iam_policy_document.assume_role_for_sfn_state_machine_policy.json
}


data "aws_iam_policy_document" "invoke_poc_lambdas_fargate_policy_document" {
  statement {
    actions = [
      "lambda:InvokeFunction",
    ]

    resources = [
      module.lambda_nr_sfn_fargate_poc_create.lambda_arn,
      module.lambda_nr_sfn_fargate_poc_metadata.lambda_arn,
      module.lambda_nr_sfn_fargate_poc_combiner.lambda_arn,
    ]
    effect = "Allow"
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:RunTask",
    ]
    resources = [
      // should target the ACTIVE one, wildcard is a fallback
      "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}",
      "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}:*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:StopTask"
    ]
    resources = [
      "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task/${var.environment}-${var.service_name}/*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "ecs:DescribeTasks"
    ]
    resources = [
      "*"
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "events:PutTargets",
      "events:PutRule",
      "events:DescribeRule"
    ]
    resources = [
      "arn:aws:events:${var.aws_region}:${data.aws_caller_identity.current.account_id}:rule/StepFunctionsGetEventsForECSTaskRule"
    ]
  }

  statement {
    effect  = "Allow"
    actions = ["iam:PassRole"]
    resources = [
      "arn:aws:iam::*:role/${var.environment}-${var.service_name}-task-role",
      "arn:aws:iam::*:role/${var.environment}-${var.service_name}-task-execution-role"
    ]
  }
}

resource "aws_iam_policy" "invoke_poc_lambdas_fargate_policy" {
  name   = "Lambda-${var.environment}-nr-snf-fargate-poc-invoke-policy"
  policy = data.aws_iam_policy_document.invoke_poc_lambdas_fargate_policy_document.json
}

resource "aws_iam_role_policy_attachment" "invoke_poc_lambdas_fargate_role_policy_attachment" {
  role = aws_iam_role.invoke_poc_lambdas_fargate_from_state_machine.name

  for_each = {
    "resources" : aws_iam_policy.invoke_poc_lambdas_fargate_policy.arn,
    "sfn" : aws_iam_policy.invoke_state_machine_policy.arn,
    "s3" : data.aws_iam_policy.s3_test_orcd_bucket_RW.arn,

  }
  policy_arn = each.value
}

resource "aws_sfn_state_machine" "nr_sfn_fargate_poc_state_machine" {
  name     = "${var.environment}-nr_sfn_fargate_poc"
  role_arn = aws_iam_role.invoke_poc_lambdas_fargate_from_state_machine.arn
  definition = templatefile("${path.module}/nr_delivery_workflow.json", {
    # add all lambda variables here.
    create_jobs_lambda_arn = module.lambda_nr_sfn_fargate_poc_create.lambda_arn,
    metadata_lambda_arn    = module.lambda_nr_sfn_fargate_poc_metadata.lambda_arn,
    combiner_lambda_arn    = module.lambda_nr_sfn_fargate_poc_combiner.lambda_arn
    fargate_arn            = module.nr_sfn_fargate_poc.fargate_cluster_arn,
    fargate_task_arn       = "arn:aws:ecs:${var.aws_region}:${data.aws_caller_identity.current.account_id}:task-definition/${var.environment}-${var.service_name}"
  })

  tags = {
    application_family = var.application_family
    environment        = var.environment
    service_name       = var.state_machine_name
    terraformed        = true
  }

  tracing_configuration {
    enabled = true
  }
}

# Invoke Step Function Policy
data "aws_iam_policy_document" "invoke_state_machine_policy_doc" {
  statement {
    actions = [
      "states:StartExecution",
      "states:ListExecutions",
    ]

    resources = [
      aws_sfn_state_machine.nr_sfn_fargate_poc_state_machine.arn
    ]
  }
}

resource "aws_iam_policy" "invoke_state_machine_policy" {
  name        = "StepFunctions-${var.environment}-${var.state_machine_name}-InvokeOnly"
  description = "Invoke CMO claiming state machine"
  policy      = data.aws_iam_policy_document.invoke_state_machine_policy_doc.json
}