provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/orcd-raw-assets/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.1"

  env                 = var.environment
  bucket_name         = var.bucket_name
  application_family  = var.application_family
  s3_read_only_policy = true
  block_public_access = true
  acceleration_status = "Enabled"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

resource "aws_s3_bucket_intelligent_tiering_configuration" "intelligent_tiering_config" {
  bucket = module.s3_bucket.s3_bucket_name_output
  name   = "${var.environment}-${var.bucket_name}-intelligent-tiering-config"

  tiering {
    access_tier = "ARCHIVE_ACCESS"
    days        = 90
  }

  tiering {
    access_tier = "DEEP_ARCHIVE_ACCESS"
    days        = 180
  }
}