module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "dev"
  profile = "dev"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/orchd-mlflow-server/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "dev.theorchard.io."
}

data "aws_s3_bucket" "artifact_bucket" {
  bucket = var.artifact_bucket
}

data "aws_s3_bucket" "previous_artifact_bucket" {
  bucket = var.previous_artifact_bucket
}

data "aws_iam_policy_document" "mlflow_s3_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:PutObject",
    ]
    resources = [
      "${data.aws_s3_bucket.artifact_bucket.arn}/*",
      "${data.aws_s3_bucket.previous_artifact_bucket.arn}/*"
    ]
  }

  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket",
    ]
    resources = [
      data.aws_s3_bucket.artifact_bucket.arn,
      data.aws_s3_bucket.previous_artifact_bucket.arn
    ]
  }
}

resource "aws_iam_policy" "mlflow_s3_policy" {
  name        = "S3-${var.environment}-${var.service_name}-RW-policy"
  description = "RW access to the ${var.artifact_s3_uri} bucket"
  policy      = data.aws_iam_policy_document.mlflow_s3_policy_document.json
}

# Sentry
module "orchd_service_sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.0"

  environment        = var.environment
  application_family = var.application_family
  platform           = "python"
  service_name       = var.service_name
}

# Orchard ML flow RDS
module "mlflow_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=5.3.0"

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family

  rds_master_username = "mlflow_dbadmin"
  rds_master_password = "s0mePass!changme"

  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_cluster_parameter_group_name       = "aurora-mysql80"
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine                                = "aurora-mysql"
  rds_engine_version                        = "8.0.mysql_aurora.3.05.2"
  rds_performance_insights_enabled          = false

  custom_kms_key_enabled = false

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.zone_id
}

# fargate environment
module "orchd_mlflow_service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.0.1"

  providers = {
    aws.dns = aws.dev
  }

  environment             = var.environment
  service_name            = var.service_name
  aws_region              = var.aws_region
  desired_task_count      = 1
  minimum_capacity        = 1
  maximum_capacity        = 1
  task_cpu                = 2048
  task_memory             = 4096
  route53_zone_id         = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                  = module.vpc_info.vpc_id
  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids
  application_family      = var.application_family
  blocking_waf_enabled    = true
  health_check_path       = "/health"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      ARTIFIACTS_URI = "${var.artifact_s3_uri}"
    },
    {
      DB_HOST = module.mlflow_rds.rds_cluster_endpoint
    },
    {
      DATABASE = module.mlflow_rds.rds_cluster_database_name
    },
    {
      DB_PORT = module.mlflow_rds.rds_cluster_port
    }
  ]

  secrets = [
    {
      DB_USERNAME = "${var.environment}/${var.service_name}/username"
    },
    {
      DB_PASSWORD = "${var.environment}/${var.service_name}/password"
    }
  ]
  iam_managed_policy_attachments = [
    aws_iam_policy.mlflow_s3_policy.arn
  ]
}


# fargate service dashboard
module "orchd_service_datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.10.0"

  environment                       = var.environment
  application_family                = var.application_family
  environment_type                  = "fargate"
  service_4xx_monitor_enabled       = false
  service_5xx_monitor_enabled       = false
  service_name                      = var.service_name
  notification_endpoints            = ""
  escalation_notification_endpoints = ""

}