provider "aws" {
  region = var.region
}

# Caller Identity
data "aws_caller_identity" "current" {}

# Terraform backends cannot contain interpolations - of the form ${var.environment}-${var.service_name}-state
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/ows-video/terraform.tfstate"
    region  = "us-east-1"
    encrypt = true
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.4.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "dev.theorchard.io."
}

data "aws_iam_policy_document" "assume_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["rds.amazonaws.com"]
    }

  }
}

resource "aws_iam_role" "upload_role" {
  name                 = "${var.environment}-ows-video-s3-upload-role"
  assume_role_policy   = data.aws_iam_policy_document.assume_role.json
  max_session_duration = 14400

  tags = {
    terraformed = "true"
  }
}

data "aws_s3_bucket" "db_data" {
  bucket = "${var.environment}-db-data"
}

module "s3_read_write_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.3.0"

  buckets = [{
    bucket = data.aws_s3_bucket.db_data.id
  }]
  action_types = ["read", "write"]
}

# Create policy for read-write access to the S3 bucket
resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-dev-ows-video-temp-RW"
  policy = module.s3_read_write_policy.policy.json
}

resource "aws_iam_role_policy_attachment" "upload_role_policy_attachment" {
  role       = aws_iam_role.upload_role.name
  policy_arn = aws_iam_policy.s3_read_write_policy.arn
}

resource "aws_rds_cluster_parameter_group" "db_parameter_group_8" {
  name        = "${var.environment}-ows-video-aurora-mysql80"
  description = "${var.environment}-ows-video-aurora-mysql80"
  family      = "aurora-mysql8.0"

  parameter {
    name         = "aws_default_s3_role"
    value        = aws_iam_role.upload_role.arn
    apply_method = "immediate"
  }

  parameter {
    name         = "aurora_binlog_replication_max_yield_seconds"
    value        = "0"
    apply_method = "immediate"
  }

  parameter {
    name         = "binlog_format"
    value        = "ROW"
    apply_method = "pending-reboot"
  }

  parameter {
    name         = "character_set_client"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_database"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_connection"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_filesystem"
    value        = "binary"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_results"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "character_set_server"
    value        = "utf8mb4"
    apply_method = "immediate"
  }

  parameter {
    name         = "collation_connection"
    value        = "utf8mb4_general_ci"
    apply_method = "immediate"
  }

  parameter {
    name         = "collation_server"
    value        = "utf8mb4_general_ci"
    apply_method = "immediate"
  }

  parameter {
    name         = "log_bin_trust_function_creators"
    value        = "1"
    apply_method = "immediate"
  }

  parameter {
    name         = "slow_query_log"
    value        = "1"
    apply_method = "immediate"
  }
}

module "ows_video_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=6.0.0"

  providers = {
    aws.dns = aws
  }

  environment                               = var.environment
  application_family                        = var.application_family
  service_name                              = "ows-video"
  rds_cluster_instance_class                = "db.t4g.medium"
  rds_cluster_instance_count                = "1"
  rds_db_subnet_group_name                  = "private_rds_subnet_group"
  rds_db_cluster_parameter_group_name       = aws_rds_cluster_parameter_group.db_parameter_group_8.name
  rds_cluster_instance_parameter_group_name = "default.aurora-mysql8.0"
  rds_engine_version                        = "8.0.mysql_aurora.3.07.1"
  rds_master_username                       = "ows_video_master"
  rds_master_password                       = "dummy123"
  custom_kms_key_enabled                    = false
  rds_performance_insights_enabled          = false
  enabled_cloudwatch_logs_exports           = ["audit", "error", "general"]
  vpc_id                                    = module.vpc_info.vpc_id
  route53_zone_id                           = data.aws_route53_zone.route53_zone.zone_id
  rds_db_cluster_iam_roles                  = [aws_iam_role.upload_role.arn]
}