data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "AWS"

      identifiers = var.additional_browser_assume_role_arns
    }
  }
}

resource "aws_iam_role" "publishing_browser_upload_role" {
  name                 = "${var.environment}-publishing-browser-upload-role"
  max_session_duration = 3600
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "publishing_browser_upload_policy_attachment" {
  role       = aws_iam_role.publishing_browser_upload_role.id
  policy_arn = aws_iam_policy.input_bucket_putonly_policy.arn
}

data "aws_iam_policy_document" "publishing_browser_upload_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    resources = [
      aws_iam_role.publishing_browser_upload_role.arn
    ]
  }
}

resource "aws_iam_policy" "publishing_browser_upload_assume_role_policy" {
  name        = "${var.environment}-publishing-browser-upload-assume-role-policy"
  description = "Assume browser upload role used by the publishing fargate role."
  policy      = data.aws_iam_policy_document.publishing_browser_upload_assume_role_policy_document.json
}