module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=2.2.4"
  acceleration_status = "Enabled"

  env         = var.environment
  bucket_name = "publishing-uploads"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  # CORS Rules
  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["PUT", "POST"]
      allowed_origins = [
        "http://localhost:*",
        "https://publishing.qaorch.com",
      ]
      expose_headers  = ["ETag"]
      max_age_seconds = 3000
    }
  ]

  lifecycle_rules_options_noncurrent_version_expiration = [
    {
      prefix  = ""
      enabled = true
      days    = 1
    }
  ]

  lifecycle_rules_abort_incomplete_multipart_upload_days = [
    {
      prefix  = "#"
      enabled = true
      days    = 1
    }
  ]
}

data "aws_iam_policy_document" "input_bucket_putonly_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "input_bucket_putonly_policy" {
  name        = "S3-${module.s3_bucket.s3_bucket_name_output}-WO"
  description = "Write access to publishing input bucket"
  policy      = data.aws_iam_policy_document.input_bucket_putonly_policy.json
}

data "aws_iam_policy_document" "input_bucket_readonly_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]
  }
}

resource "aws_iam_policy" "input_bucket_readonly_policy" {
  name        = "S3-${module.s3_bucket.s3_bucket_name_output}-RO"
  description = "Read access to publishing input bucket"
  policy      = data.aws_iam_policy_document.input_bucket_readonly_policy.json
}