provider "snowflake" {
  organization_name = "sme"
  account_name      = "orchard"
  role              = "PROD_ATLANTIS"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/snowflake-s3-integrations/collaborators/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
}

locals {
  snowflake_integration_role_name = "${var.environment}-${var.application_family}-snowflake-integration-role"
}

resource "aws_iam_role" "integration_role" {
  name = local.snowflake_integration_role_name

  assume_role_policy = data.aws_iam_policy_document.assume_role_policy.json

  inline_policy {
    name   = "${var.environment}-${var.application_family}-bucket-snowflake-policy"
    policy = data.aws_iam_policy_document.inline_policy.json
  }
}

data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type        = "AWS"
      identifiers = ["arn:aws:iam::494544507972:user/c_orchard_stage_volume"]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values   = ["ORCHARD_SFCRole=881_jVh6jc4V/cJx8vt6tEbYRL/TePY="]
    }
  }
}

module "bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.15.6"

  env                = var.environment
  bucket_name        = "collaborators-reports-test"
  application_family = var.application_family

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

data "aws_iam_policy_document" "inline_policy" {
  statement {
    actions = [
      "s3:PutObject",
      "s3:GetObject",
      "s3:GetObjectVersion",
      "s3:DeleteObject",
      "s3:DeleteObjectVersion"
    ]
    resources = ["${module.bucket.s3_bucket_arn_output}/*"]
  }

  statement {
    actions = [
      "s3:ListBucket",
      "s3:GetBucketLocation"
    ]
    resources = [module.bucket.s3_bucket_arn_output]
  }
}