module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.env
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.region
  alias   = "dev"
  profile = "dev"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/split-synchronizer/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.4.0"

  environment = var.env
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.0.0"

  providers = {
    aws.dns = aws
  }

  environment                      = var.env
  service_name                     = var.service_name
  application_family               = var.application_family
  cache_engine                     = "redis"
  cache_subnet_group_name          = "${var.env}-elasticache-group"
  additional_cidr_blocks_enabled   = true
  cache_transit_encryption_enabled = false
  cache_node_type                  = "cache.t4g.small"
}
module "split_synchronizer_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.2.0"

  providers = {
    aws.dns = aws.dev
  }

  environment             = var.env
  service_name            = var.service_name
  aws_region              = var.region
  application_family      = var.application_family
  commit_sha              = "latest"
  container_port          = "3010"
  task_type               = "web_service"
  desired_task_count      = 1
  task_cpu                = 256
  task_memory             = 512
  maximum_capacity        = 1
  minimum_capacity        = 1
  vpc_id                  = module.vpc_info.vpc_id
  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids
  health_check_path       = "/admin/ping"

  iam_managed_policy_attachments = [
    "arn:aws:iam::aws:policy/CloudWatchFullAccess"
  ]

  environment_variables = [
    {
      SPLIT_SYNC_REDIS_HOST = module.elasticache.redis_primary_endpoint_address
    },
    {
      SPLIT_SYNC_REDIS_PORT = "6379"
    },
    {
      SPLIT_SYNC_ADVANCED_PARAMETERS = "-config /var/app/config.json"
    }
  ]

  secrets = [
    {
      SPLIT_SYNC_API_KEY = "${var.env}/${var.service_name}/SPLIT_SYNC_API_KEY"
    }
  ]
}