module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "dev"
  profile = "dev"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/streamlit-audience/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.4.0"

  environment = var.environment
}

data "aws_s3_bucket" "selected" {
  bucket = var.application_bucket
}

module "streamlit-audience-feedback-table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=3.3.1"

  application_family             = var.application_family
  env                            = var.environment
  hash_key                       = "user"
  range_key                      = "artist"
  range_key_enabled              = true
  server_side_encryption_enabled = true
  table_name                     = var.dynamo_table
  use_on_demand                  = true
  use_custom_table_name          = true
  custom_table_name              = var.dynamo_table

  attribute = [
    {
      name = "user"
      type = "S"
    },
    {
      name = "artist"
      type = "S"
    }
  ]
}

# Create policy to access DynamoDB table from app
data "aws_iam_policy_document" "streamlit_audience_dynamodb_policy_document" {
  statement {
    actions = [
      "dynamodb:GetItem",
      "dynamodb:PutItem",
      "dynamodb:Query",
      "dynamodb:UpdateItem",
      "dynamodb:Scan",
    ]
    effect = "Allow"
    resources = [
      module.streamlit-audience-feedback-table.aws_dynamodb_table_arn_with_sort_key
    ]
  }
}

resource "aws_iam_policy" "streamlit_audience_dynamodb_policy" {
  name   = "dynamo-${var.environment}-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.streamlit_audience_dynamodb_policy_document.json
}

# Create policy to access S3 bucket from app
data "aws_iam_policy_document" "streamlit_audience_s3_policy_document" {
  statement {
    actions = [
      "s3:GetBucketLocation",
      "s3:GetObject*",
    ]

    resources = [
      "${data.aws_s3_bucket.selected.arn}/*"
    ]
  }

  statement {
    actions = [
      "s3:ListBucket",
    ]

    resources = [
      data.aws_s3_bucket.selected.arn
    ]
  }
}

resource "aws_iam_policy" "streamlit_audience_s3_policy" {
  name   = "S3-${var.environment}-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.streamlit_audience_s3_policy_document.json
}

module "streamlit_audience_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.dev
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  vpc_id                  = module.vpc_info.vpc_id
  fargate_service_subnets = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets   = module.vpc_info.default_private_subnet_ids


  desired_task_count = 1
  minimum_capacity   = 1
  maximum_capacity   = 1
  task_cpu           = 1024
  task_memory        = 8192

  health_check_path = "/healthz/"

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = var.environment
    },
  ]

  secrets = [
  ]

  iam_managed_policy_attachments = [
    aws_iam_policy.streamlit_audience_s3_policy.arn,
    aws_iam_policy.streamlit_audience_dynamodb_policy.arn,
  ]
}


module "streamlit_audience_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.16.1"

  environment                 = var.environment
  environment_type            = "fargate"
  service_name                = var.service_name
  service_4xx_monitor_enabled = false
  application_family          = var.application_family

  notification_endpoints            = "@slack-fansifter-team-dev"
  escalation_notification_endpoints = "@slack-fansifter"

}


module "streamlit_audience_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}