resource "aws_cloudfront_distribution" "documents_assets" {
  # checkov:skip=CKV_AWS_68:Rule disabled for dev env.
  # checkov:skip=CKV_AWS_310:Rule disabled for dev env.
  # checkov:skip=CKV2_AWS_47:Rule disabled for dev env.
  # checkov:skip=CKV_AWS_374:Rule disabled for dev env.
  enabled             = true
  is_ipv6_enabled     = false
  comment             = "Distribution for Stripo v2 documents assets"
  price_class         = "PriceClass_All"
  http_version        = "http2"
  aliases             = ["${var.environment}-${var.documents_domain}.${var.environment}.theorchard.io"]
  default_root_object = "index.html"

  origin {
    domain_name              = "${module.s3_bucket.s3_bucket_name_output}.s3.amazonaws.com"
    origin_id                = "S3-${module.s3_bucket.s3_bucket_name_output}"
    origin_access_control_id = aws_cloudfront_origin_access_control.documents.id
  }

  default_cache_behavior {
    viewer_protocol_policy = "https-only"
    compress               = false
    allowed_methods        = ["GET", "HEAD", "OPTIONS"]
    cached_methods         = ["GET", "HEAD"]

    response_headers_policy_id = data.aws_cloudfront_response_headers_policy.response_headers_policy.id

    target_origin_id = "S3-${module.s3_bucket.s3_bucket_name_output}"
    min_ttl          = 0
    default_ttl      = 86400
    max_ttl          = 31536000

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
      headers = [
        "Origin",
        "Access-Control-Request-Headers",
        "Access-Control-Request-Method",
      ]
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  logging_config {
    include_cookies = false
    bucket          = var.cloudfront_logs_bucket
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }
}

resource "aws_cloudfront_distribution" "editor_assets" {
  # checkov:skip=CKV_AWS_68:Rule disabled for dev env.
  # checkov:skip=CKV_AWS_310:Rule disabled for dev env.
  # checkov:skip=CKV2_AWS_47:Rule disabled for dev env.
  # checkov:skip=CKV_AWS_374:Rule disabled for dev env.
  enabled             = true
  is_ipv6_enabled     = false
  comment             = "Distribution for Stripo v2 editor assets"
  price_class         = "PriceClass_All"
  http_version        = "http2"
  aliases             = ["${var.environment}-${var.editor_assets_domain}.${var.environment}.theorchard.io"]
  default_root_object = "index.html"

  origin {
    domain_name              = "${module.assets_bucket.s3_bucket_name_output}.s3.amazonaws.com"
    origin_id                = "S3-${module.assets_bucket.s3_bucket_name_output}"
    origin_access_control_id = aws_cloudfront_origin_access_control.editor_assets.id
  }

  default_cache_behavior {
    viewer_protocol_policy = "https-only"
    compress               = true
    allowed_methods        = ["GET", "HEAD", "OPTIONS"]
    cached_methods         = ["GET", "HEAD"]

    response_headers_policy_id = aws_cloudfront_response_headers_policy.editor_assets.id

    target_origin_id = "S3-${module.assets_bucket.s3_bucket_name_output}"
    min_ttl          = 0
    default_ttl      = 86400
    max_ttl          = 31536000

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
      headers = [
        "Origin",
        "Access-Control-Request-Headers",
        "Access-Control-Request-Method",
      ]
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  logging_config {
    include_cookies = false
    bucket          = var.cloudfront_logs_bucket
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }
}

data "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name = "Managed-SimpleCORS"
}

resource "aws_cloudfront_response_headers_policy" "editor_assets" {
  name = "${var.environment}-${var.service_name}-editor-assets"

  cors_config {
    access_control_allow_credentials = false
    origin_override                  = true

    access_control_allow_headers {
      items = ["*"]
    }

    access_control_allow_methods {
      items = ["GET", "HEAD", "OPTIONS"]
    }

    access_control_allow_origins {
      items = ["*"]
    }
  }

  security_headers_config {
    content_type_options {
      override = true
    }

    frame_options {
      frame_option = "DENY"
      override     = true
    }

    referrer_policy {
      referrer_policy = "same-origin"
      override        = true
    }

    strict_transport_security {
      access_control_max_age_sec = 63072000
      include_subdomains         = true
      preload                    = true
      override                   = true
    }

    xss_protection {
      mode_block = true
      protection = true
      override   = true
    }
  }

  custom_headers_config {
    items {
      header   = "Cache-Control"
      override = true
      value    = "no-store"
    }
  }
}

resource "aws_cloudfront_origin_access_control" "documents" {
  name                              = "${var.environment}-${var.service_name}"
  description                       = "${var.environment}-${var.service_name} Policy"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"
}

resource "aws_cloudfront_origin_access_control" "editor_assets" {
  name                              = "${var.environment}-${var.service_name}-editor-assets"
  description                       = "${var.environment}-${var.service_name} Editor Assets Policy"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"
}

resource "aws_route53_record" "documents_cdn" {
  name    = "${var.environment}-${var.documents_domain}"
  zone_id = data.aws_route53_zone.dev.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.documents_assets.domain_name]
}