module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = "integrations"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "dev-orcd-terraform-state"
    key     = "dev/virtual-sales-rep/rds/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

resource "aws_rds_cluster_parameter_group" "db_parameter_group" {
  name        = "${var.environment}-${var.service_name}-aurora-postgresql17"
  description = "${var.environment}-${var.service_name}-aurora-postgresql17"
  family      = "aurora-postgresql17"
}

module "virtual_sales_rep_rds" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=8.0.0"

  providers = {
    aws.dns = aws
  }

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  rds_engine                 = "aurora-postgresql"
  rds_engine_version         = "17"
  rds_cluster_instance_count = 1
  rds_cluster_instance_class = "db.t4g.medium"
  rds_port                   = 5432

  rds_db_subnet_group_name                  = "private_rds_subnet_group"
  rds_db_cluster_parameter_group_name       = aws_rds_cluster_parameter_group.db_parameter_group.name
  rds_cluster_instance_parameter_group_name = "default.aurora-postgresql17"

  # Credentials — initial values only; rotate out-of-band after apply.
  rds_master_username = "dummy"
  rds_master_password = "dummy123"

  rds_backup_retention_period     = 7
  enabled_cloudwatch_logs_exports = ["postgresql"]
  custom_kms_key_enabled          = false

  vpc_id = module.vpc_info.vpc_id
}