module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "prod-dx-terraform-state"
    key     = "prod/dx-ui-service/terraform.tfstate"
    region  = "eu-central-1"
    encrypt = "true"
  }
}

data "aws_lb_target_group" "dx_ui_service_proxy_alb_tg" {
  name = "${var.environment}-dx-proxy-ui-svc-tg"
}

data "aws_subnets" "private_subnets" {
  filter {
    name = "tag:Name"
    values = [
      "prod_private_subnet*",
    ]
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  provider = aws.networking

  name = "${var.domain_name}."
}

data "aws_acm_certificate" "smedx_net" {
  domain   = "*.${var.domain_name}"
  statuses = ["ISSUED"]
}

data "aws_security_group" "dx_proxy_alb_security_group" {
  name = "${var.environment}-dx-proxy-alb-sg"
}

module "dx_ui_service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.3"

  providers = {
    aws.dns = aws.networking
  }

  application_family                       = var.application_family
  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  desired_task_count                       = 2
  minimum_capacity                         = 2
  maximum_capacity                         = 4
  task_cpu                                 = 2048
  task_memory                              = 4096
  health_check_path                        = "/dx-ui-service/api/v1/actuator/health"
  override_route53_zone_id                 = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = data.aws_subnets.private_subnets.ids
  load_balancer_subnets                    = data.aws_subnets.private_subnets.ids
  load_balancer_access_logs_s3_bucket_name = "shared-orcd-lb-logs-eu-central-1"
  enable_centralized_alb_logs              = false
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.smedx_net.arn)[1]
  ows_machine_to_machine_enabled           = false
  splitio_enabled                          = false
  non_ecr_image                            = "086679231553.dkr.ecr.us-east-1.amazonaws.com/dx-ui-service:latest"

  additional_lb_target_group_arns = [
    data.aws_lb_target_group.dx_ui_service_proxy_alb_tg.arn
  ]

  iam_managed_policy_attachments = []

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SPRING_PROFILES_ACTIVE = "local"
    },
    {
      SERVER_PORT = "8080"
    },
    {
      SPRING_DATASOURCE_URL = "jdbc:postgresql://grpsp-prod-ff-writer-pgb-01.smearsys.com:6432/ar_db"
    },
    {
      SPRING_DATASOURCE_USERNAME = "admdxd"
    },
    {
      CORS_ALLOWED_ORIGINS = "https://prod-dx.smedx.net,https://prod.smedx.net"
    },
    {
      DD_PROFILING_ENABLED = true
    }
  ]

  secrets = [
    {
      SPRING_DATASOURCE_PASSWORD = "${var.environment}/${var.service_name}/SPRING_DATASOURCE_PASSWORD"
    }
  ]
}

# Allow inbound traffic from proxy ALB to dx-ui-service ECS tasks
resource "aws_security_group_rule" "allow_proxy_alb_to_dx_ui_service_tasks" {
  type                     = "ingress"
  from_port                = 8080
  to_port                  = 8080
  protocol                 = "TCP"
  source_security_group_id = data.aws_security_group.dx_proxy_alb_security_group.id
  security_group_id        = module.dx_ui_service_fargate_environment.fargate_security_group_id
  description              = "Allow traffic from proxy ALB to dx-ui-service tasks"
}

module "dx_ui_service_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.18.1"

  environment                       = var.environment
  environment_type                  = "fargate"
  service_name                      = var.service_name
  application_family                = var.application_family
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}

module "dx_ui_service_secrets_manager" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment        = var.environment
  service_name       = var.service_name
  application_family = var.application_family
  secret_name        = each.value
}