module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = "devops"
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  profile = "networking"
  alias   = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-ecommerce-terraform-state"
    key     = "qa/theorchard.io/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_acm_certificate" "tls_cert" {
  #checkov:skip=CKV2_AWS_71:domain name needs to include wildcard
  domain_name               = "*.${var.domain_name}"
  subject_alternative_names = [var.domain_name]
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment = var.environment
    terraformed = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn = aws_acm_certificate.tls_cert.arn
  validation_record_fqdns = [
    for validation_object in aws_acm_certificate.tls_cert.domain_validation_options : validation_object.resource_record_name
  ]

  depends_on = [
    aws_route53_record.dns_validation_record_networking,
  ]
}

data "aws_route53_zone" "main_domain_networking" {
  provider = aws.networking
  name     = var.domain_name
}

resource "aws_route53_record" "dns_validation_record_networking" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert.domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    }
  }

  provider = aws.networking

  allow_overwrite = true
  name            = each.value.name
  records         = [each.value.record]
  ttl             = 60
  type            = each.value.type
  zone_id         = data.aws_route53_zone.main_domain_networking.zone_id
}