resource "aws_ecs_task_definition" "csa-stage" {
  family                   = "${lower(var.vpc_name)}-csa-stage-td"
  network_mode             = "awsvpc"
  requires_compatibilities = ["FARGATE"]
  cpu                      = "1024"
  memory                   = "4096"
  execution_role_arn       = "arn:aws:iam::718729873097:role/ecsTaskExecutionRole"
  task_role_arn            = "arn:aws:iam::718729873097:role/csa-task-role"

  container_definitions = jsonencode([
    {
      name      = "csa"
      image     = "718729873097.dkr.ecr.eu-central-1.amazonaws.com/csa:5.4.119"
      essential = true

      portMappings = [{
        containerPort = 8080
        hostPort      = 8080
        protocol      = "tcp"
      }]

      healthCheck = {
        command     = ["CMD-SHELL", "curl -f http://localhost:8080/csa/actuator/health || exit 1"]
        interval    = 30
        timeout     = 5
        retries     = 3
        startPeriod = 60
      }

      environment = [
        { name = "SPRING_PROFILES_ACTIVE", value = "stage" },
        { name = "JAVA_TOOL_OPTIONS", value = "-XX:+UseContainerSupport" }
      ]

      secrets = [
      {
        name      = "DB_PASSWORD"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/stage-amzooe:DB_PASSWORD::"
      },
      {
        name      = "CLIENT_SECRET"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/stage-amzooe:CLIENT_SECRET::"
      },
      {
        name      = "AOMA_AUTH_PASSWORD"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/stage-amzooe:AOMA_AUTH_PASSWORD::"
      },
      {
        name      = "AOMA_ATTEMPT_PASSWORD"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/stage-amzooe:AOMA_ATTEMPT_PASSWORD::"
      },
      {
        name      = "AOMA_STATUS_PASSWORD"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/stage-amzooe:AOMA_STATUS_PASSWORD::"
      },
      {
        name      = "RDX_CLIENT_SECRET"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/stage-amzooe:RDX_CLIENT_SECRET::"
      },
      {
        name      = "VAULT_TOKEN"
        valueFrom = "arn:aws:secretsmanager:eu-central-1:718729873097:secret:csa/vault-iGyd8d"
      }
      ]
  

      logConfiguration = {
        logDriver = "awslogs"
        options = {
          awslogs-region        = var.region
          awslogs-group         = "/ecs/csa-stage"
          awslogs-stream-prefix = "ecs"
        }
      }
    }
  ])
}

resource "aws_ecs_service" "csa-stage" {
  name                  = "${lower(var.vpc_name)}-csa-stage"
  cluster               = "arn:aws:ecs:eu-central-1:718729873097:cluster/csa-cluster"
  task_definition       = aws_ecs_task_definition.csa-stage.arn
  desired_count         = 1
  launch_type           = "FARGATE"
  platform_version      = "LATEST"
  enable_execute_command = true

  network_configuration {
    subnets         = [aws_subnet.DIGSYS-S3-IAPP-1A.id, aws_subnet.DIGSYS-S3-IAPP-1B.id]
    security_groups = [aws_security_group.DIGSYS-S3-CSA2APP01-SG.id]
    assign_public_ip = false
  }

  deployment_minimum_healthy_percent = 50
  deployment_maximum_percent         = 200

  load_balancer {
    target_group_arn = aws_lb_target_group.digsys-s3-csa2-stage[0].arn
    container_name   = "csa"
    container_port   = 8080
  }

  depends_on = [aws_lb_listener.digsys-s3-csa2-int01[0]]
}


resource "aws_cloudwatch_metric_alarm" "csa_stage_running_count_low" {
  alarm_name          = "${lower(var.vpc_name)}-csa-stage-running-count-low"
  alarm_description   = "Triggers when RunningTaskCount for csa-stage is less than 1"
  namespace           = "ECS/ContainerInsights"
  metric_name         = "RunningTaskCount"
  dimensions = {
    ClusterName = "csa-cluster"
    ServiceName = aws_ecs_service.csa-stage.name
  }
  statistic           = "Minimum"
  period              = 60
  evaluation_periods  = 1
  threshold           = 1
  comparison_operator = "LessThanThreshold"
  treat_missing_data  = "missing"
  alarm_actions = [aws_sns_topic.csa_stage_alerts.arn]
  ok_actions    = [aws_sns_topic.csa_stage_alerts.arn]
}