module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.lambda_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/examples/lambda/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

module "lambda_app_name_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=5.0.0"

  environment        = var.environment
  platform           = "python"
  service_name       = var.lambda_name
  application_family = var.application_family
  teams              = [var.environment]
}

module "lambda_app_name_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.1.0"

  environment_name = var.environment
  service_name     = var.lambda_name
}

module "lambda_app_name" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"

  environment         = var.environment
  lambda_name         = var.lambda_name
  application_family  = var.application_family
  lambda_description  = "Does what a lambda might do"
  use_container_image = true

  lambda_function_timeout                        = 300
  lambda_function_memory_size                    = 128
  lambda_function_reserved_concurrent_executions = 3

  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids

  iam_managed_policy_attachments = [
    module.lambda_app_name_owsrequest.policy_arn_output,
  ]

  lambda_function_environment_variables = {
    Environment = var.environment,
    SENTRY_DSN  = module.lambda_app_name_sentry_project.sentry_key_dsn_public_output,
  }
}

module "lambda_app_name_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.7"

  environment                       = var.environment
  service_name                      = var.lambda_name
  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints
}