module "s3_read_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [
    {
      bucket = module.s3_bucket.s3_bucket_name_output
    }
  ]
  action_types = ["read"]
}

resource "aws_iam_policy" "s3_read_policy" {
  name   = "S3-${module.s3_bucket.s3_bucket_name_output}-RO"
  policy = module.s3_read_policy.policy.json
}

module "s3_read_write_policy" {
  source = "git@github.com:theorchard/terraform-iam-policy-templates.git//documents/s3/buckets_with_prefixes?ref=0.4.0"

  buckets = [
    {
      bucket = module.s3_bucket.s3_bucket_name_output
    }
  ]
  action_types          = ["read", "write", "delete"]
  enable_global_actions = true
}

resource "aws_iam_policy" "s3_read_write_policy" {
  name   = "S3-${module.s3_bucket.s3_bucket_name_output}-RW"
  policy = module.s3_read_write_policy.policy.json
}

data "aws_iam_policy_document" "snowflake_integration_role_assume_role_policy" {
  statement {
    actions = ["sts:AssumeRole"]
    effect  = "Allow"

    principals {
      type = "AWS"
      identifiers = [
        "arn:aws:iam::212740118925:user/91n1-s-vast5230"
      ]
    }

    condition {
      test     = "StringEquals"
      variable = "sts:ExternalId"
      values = [
        "DELPHI_SFCRole=2_6Trbqo16upG3th5m3VRXuSYWtxw="
      ]
    }
  }
}

resource "aws_iam_role" "snowflake_integration_role" {
  name               = local.iam_role_name
  assume_role_policy = data.aws_iam_policy_document.snowflake_integration_role_assume_role_policy.json
}

resource "aws_iam_role_policy_attachment" "triggered_send_snowflake_integration_role_attachment" {
  policy_arn = aws_iam_policy.s3_read_write_policy.arn
  role       = aws_iam_role.snowflake_integration_role.name
}