provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "prod-fansifter-terraform-state"
    key     = "prod/lambda-audience/sendgrid-webhooks-inbound/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.0.0"

  environment = var.environment
}

data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

data "aws_elasticache_replication_group" "ows_email_campaigns_redis_cache" {
  replication_group_id = "${var.environment}-ows-email-campaigns"
}

module "lambda_audience_sendgrid_webhooks_inbound" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"
  lambda_name        = var.lambda_name
  lambda_description = "Lambda to process Sendgrid Webhooks for inbound emails"
  environment        = var.environment
  application_family = var.application_family

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids

  use_container_image = true

  datadog_advanced_enabled = true

  lambda_function_timeout                        = var.lambda_timeout
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_reserved_concurrency

  lambda_function_environment_variables = {
    ENVIRONMENT                           = var.environment
    SENTRY_DSN                            = module.sentry.sentry_key_dsn_public_output
    KAFKA_BOOTSTRAP_SERVERS               = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    FAILED_EVENTS_S3_BUCKET               = data.aws_s3_bucket.dead_letter_events_bucket.bucket
    SNOWFLAKE_ACCOUNT                     = var.snowflake_account
    SNOWFLAKE_DATABASE                    = var.snowflake_database
    SNOWFLAKE_SCHEMA                      = var.snowflake_schema
    SNOWFLAKE_WAREHOUSE                   = var.snowflake_warehouse
    SNOWFLAKE_ROLE                        = var.snowflake_role
    SNOWFLAKE_USER                        = var.snowflake_user
    SNOWFLAKE_PRIVATE_KEY_SECRET_NAME     = local.snowflake_private_key_secret_name
    SNOWFLAKE_KEY_PASSPHRASE_SECRET_NAME  = local.snowflake_key_passphrase_secret_name
    SENDGRID_SME_API_KEY_SECRET_NAME      = local.sendgrid_sme_api_key_secret_name
    REPLY_TO_SECRET_KEY_NAME              = local.reply_to_secret_key_name
    DEFAULT_FORWARD_EMAIL                 = var.default_forward_email
    FROM_EMAIL_DOMAIN                     = var.from_email_domain
    REDIS_HOST                            = data.aws_elasticache_replication_group.ows_email_campaigns_redis_cache.primary_endpoint_address
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_extra_read_policy.arn,
    data.aws_iam_policy.refresh_m2m_token_read_policy.arn,
    aws_iam_policy.lambda_s3_policy.arn,
  ]
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.17.1"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}