provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "prod-fansifter-terraform-state"
    key     = "prod/lambda-audience/songwhip-fan-consent-handler/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.0.0"

  environment = var.environment
}

data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

data "aws_elasticache_replication_group" "ows_preference_center_redis" {
  replication_group_id = "${var.environment}-ows-preference-center"
}

data "aws_iam_policy_document" "songwhip_send_email_policy" {
  statement {
    effect    = "Allow"
    resources = [
      "arn:aws:ses:us-east-1:${var.songwhip_aws_account}:identity/songwhip.com"
    ]
    actions = [
      "ses:SendEmail",
      "ses:SendRawEmail",
    ]
  }
}

resource "aws_iam_policy" "songwhip_send_email_policy" {
  name   = "SES-${var.environment}-${var.service_name}-send-email-policy"
  policy = data.aws_iam_policy_document.songwhip_send_email_policy.json
}

data "aws_iam_policy" "refresh_m2m_token_read_policy" {
  name  = "SecretsManager-${var.environment}-refresh-m2m-token-read-policy"
}

module "lambda" {
# checkov:skip=CKV_AWS_116:Silencing Checkov false warning as the DLQ is actually enabled
  source                  = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"
  lambda_name             = var.lambda_name
  lambda_description      = "Lambda to process Songwhip fan consent events from Amazon MSK service"
  lambda_function_timeout = 14 * 60
  environment             = var.environment
  application_family      = var.application_family

  lambda_function_memory_size = 256

  lambda_function_reserved_concurrent_executions = 1

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids

  use_container_image = true

  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT             = var.environment
    SENTRY_DSN              = module.sentry.sentry_key_dsn_public_output
    REDIS_HOST              = data.aws_elasticache_replication_group.ows_preference_center_redis.primary_endpoint_address
    SONGWHIP_AWS_ACCOUNT_ID = var.songwhip_aws_account

  }

  msk_event_enabled                             = true
  event_source_mapping_msk_cluster_name         = "${var.environment}-${var.msk_cluster_name}"
  event_source_mapping_msk_cluster_uuid         = var.msk_cluster_uuid
  event_source_mapping_batch_size               = var.msk_event_source_mapping_batch_size
  event_source_mapping_batch_window             = var.msk_event_source_mapping_batch_window
  event_source_mapping_filter_criteria_pattern  = var.event_source_mapping_filter_criteria_pattern
  msk_topics = [
    "event.songwhip.fan.consent"
  ]

  iam_managed_policy_attachments = [
    aws_iam_policy.songwhip_send_email_policy.arn,
    data.aws_iam_policy.refresh_m2m_token_read_policy.arn,
  ]
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.0.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.6.0"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}