provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "prod-fansifter-terraform-state"
    key     = "prod/lambda-audience/test-audiences-cleanup/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.3.0"

  environment = var.environment
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.2.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}

module "lambda_audience_test_audiences_cleanup" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.6"
  lambda_name        = var.lambda_name
  lambda_description = "Lambda to clean outdated test audiences"
  environment        = var.environment
  application_family = var.application_family

  lambda_function_timeout                        = var.lambda_timeout
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_reserved_concurrency

  lambda_function_environment_variables = {
    ENVIRONMENT                   = var.environment
    SENTRY_DSN                    = module.sentry.sentry_key_dsn_public_output
    DMP_KMS_KEY_ID                = var.ows_dmp_kms_key_id
    POSTGRES_HOST                 = var.postgres_host
    POSTGRES_PORT                 = var.postgres_port
    POSTGRES_NAME                 = var.postgres_name
    POSTGRES_USERNAME             = var.postgres_username
    POSTGRES_PASSWORD_SECRET_NAME = local.postgres_password_secret_name
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.kms_policy.arn,
  ]

  use_container_image = true

  datadog_advanced_enabled = true

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.0"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.10.1"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}