module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}


terraform {
  backend "s3" {
    bucket  = "prod-fansifter-terraform-state"
    key     = "prod/ows-url-shortener/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = var.domain_name
}

data "aws_route53_zone" "theorchard_io_route53_zone" {
  provider = aws.networking

  name = "theorchard.io"
}


data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}


resource "aws_route53_record" "load_balancer_route53_record_external" {
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  name    = "${var.environment}-${var.service_name}-external.${var.domain_name}"
  type    = "A"

  alias {
    name                   = module.ows_url_shortener_fargate_environment.fargate_load_balancer_dns_name
    zone_id                = module.ows_url_shortener_fargate_environment.fargate_load_balancer_dns_zone_id
    evaluate_target_health = true
  }
}

resource "aws_route53_record" "load_balancer_theorchard_io_route53_record_external" {
  provider = aws.networking

  zone_id = data.aws_route53_zone.theorchard_io_route53_zone.zone_id
  name    = "${var.environment}-${var.service_name}-external.theorchard.io"
  type    = "A"

  alias {
    name                   = module.ows_url_shortener_fargate_environment.fargate_load_balancer_dns_name
    zone_id                = module.ows_url_shortener_fargate_environment.fargate_load_balancer_dns_zone_id
    evaluate_target_health = true
  }
}

module "ows_url_shortener_fargate_environment" {
  # checkov:skip=CKV2_AWS_28:Ensure public facing ALB are protected by WAF
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.1.0"

  providers = {
    aws.dns = aws
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  desired_task_count                       = 2
  minimum_capacity                         = 2
  maximum_capacity                         = 4
  task_cpu                                 = 1024
  task_memory                              = 2048
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  fargate_service_subnets                  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets                    = module.vpc_info.default_public_subnet_ids
  load_balancer_is_internal                = false
  route53_record_creation_enabled          = false

  additional_lb_target_group_arns = [aws_lb_target_group.ows_url_shortener_internal_tg.arn]

  splitio_enabled                = false
  ows_machine_to_machine_enabled = false

  iam_managed_policy_attachments = [
    aws_iam_policy.dynamodb_access_policy.arn,
    aws_iam_policy.files_upload_s3_policy.arn,
  ]

  environment_variables = [
    {
      ENVIRONMENT = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      SENTRY_DSN = module.sentry.sentry_key_dsn_public_output
    },
    {
      DYNAMODB_TABLENAME = module.dynamodb_table.aws_dynamodb_table_id
    },
    {
      KAFKA_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    },
    {
      ALLOWED_DOMAINS = jsonencode(var.allowed_domains)
    },
    {
      FAILED_EVENTS_S3_BUCKET = module.ows_url_shortener_s3_bucket.s3_bucket_name_output
    },
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.9"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.application_family]

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"
  service_4xx_monitor_enabled             = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}

module "sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
}