module "fan_triggered_sends_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"

  environment        = var.environment
  teams              = [var.environment]
  service_name       = var.service_name
  application_family = var.application_family
  platform           = "python"
}

module "fan_triggered_sends_lambda" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"

  environment        = var.environment
  application_family = var.application_family
  lambda_name        = var.triggered_sends_lambda_name

  use_container_image                            = true
  lambda_description                             = "Triggered by new S3 files in fan response bucket."
  vpc_enabled                                    = true
  vpc_id                                         = module.vpc_info.vpc_id
  vpc_subnet_ids                                 = module.vpc_info.default_private_subnet_ids
  datadog_enabled                                = true
  datadog_advanced_enabled                       = true
  lambda_function_reserved_concurrent_executions = 100
  lambda_function_timeout                        = 300

  lambda_function_environment_variables = {
    ENVIRONMENT                      = var.environment
    LOGGER_LEVEL                     = "INFO"
    SENTRY_DSN                       = module.fan_triggered_sends_sentry_project.sentry_key_dsn_public_output
    REDIS_HOST                       = module.redis_elasticache.redis_cluster_cname_output[0]
    REDIS_PORT                       = var.redis_port
    MARKETING_CLOUD_TOKEN_API_URL    = var.marketing_cloud_token_api_url
    KAFKA_BOOTSTRAP_SERVERS          = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    KAFKA_SECURITY_PROTOCOL          = var.kafka_security_protocol
    SUCCESSFUL_TRIGGERED_SENDS_TOPIC = var.successful_triggered_sends_topic
    FAILED_TRIGGERED_SENDS_TOPIC     = var.failed_triggered_sends_topic
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.s3_policy.arn,
  ]
}

module "lambda_fan_triggered_sends_secrets" {
  source             = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  secret_name        = "MARKETING_CLOUD_API_CREDENTIALS"
  environment        = var.environment
  service_name       = var.triggered_sends_lambda_name
  application_family = var.application_family
}

module "fan_triggered_sends_datadog_monitoring" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.18.2"

  environment  = var.environment
  service_name = var.service_name
  teams        = ["kdh"]

  notification_endpoints = "@slack-kafka-data-highway-alerts"
}

resource "aws_lambda_permission" "fan_triggered_sends_lambda_s3_permission" {
  statement_id  = "AllowS3Invoke"
  action        = "lambda:InvokeFunction"
  function_name = module.fan_triggered_sends_lambda.lambda_arn
  principal     = "s3.amazonaws.com"
  source_arn    = module.s3_bucket.s3_bucket_arn_output
}

resource "aws_s3_bucket_notification" "fan_triggered_sends" {
  bucket = module.s3_bucket.s3_bucket_name_output

  lambda_function {
    lambda_function_arn = module.fan_triggered_sends_lambda.lambda_arn
    events              = ["s3:ObjectCreated:*"]
    filter_prefix       = "${var.triggered_sends_dir}/"
  }

  depends_on = [
    aws_lambda_permission.fan_triggered_sends_lambda_s3_permission
  ]
}

data "aws_iam_policy_document" "s3_policy" {
  statement {
    actions = [
      "s3:GetObject",
      "s3:DeleteObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/*"
    ]
  }
}

resource "aws_iam_policy" "s3_policy" {
  name   = "S3-${var.environment}-${var.triggered_sends_lambda_name}-read-delete-policy"
  policy = data.aws_iam_policy_document.s3_policy.json
}