module "subscription_salesforce_credentials" {
  source = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"

  environment                    = var.environment
  application_family             = var.application_family
  additional_tags                = var.additional_tags
  service_name                   = local.subscription_service_name
  secret_name                    = "sforce_subscription_preference_creds"
  secret_recovery_window_in_days = 7
}

# Salesforce Sink connector for Subscription Preference updates
module "kafka_sforce_sink_subscription_preference_updates_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=6.4.1"

  providers = {
    aws.dns = aws.networking
  }

  environment                       = var.environment
  application_family                = var.application_family
  additional_tags                   = var.additional_tags
  service_name                      = local.subscription_service_name
  non_ecr_image                     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/${local.ecr_image_name}:latest"
  aws_region                        = var.aws_region
  desired_task_count                = 1
  minimum_capacity                  = 1
  maximum_capacity                  = 2
  task_cpu                          = 1024
  task_memory                       = 3072
  container_port                    = 8083
  health_check_grace_period_seconds = 180
  blocking_waf_enabled              = true
  health_check_path                 = "/connectors/${local.subscription_service_name}"
  web_service_health_check_command  = "[[ $(curl -s http://localhost:8083/connectors/${local.subscription_service_name}/status | jq -r '.tasks[].state' | sort | uniq) == 'RUNNING' ]] || exit 1"

  vpc_id                   = module.vpc_info.vpc_id
  fargate_service_subnets  = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets    = module.vpc_info.default_private_subnet_ids
  propagate_tags           = true
  datadog_custom_image     = "086679231553.dkr.ecr.${var.aws_region}.amazonaws.com/orchard-datadog-agent-jmx:latest"
  # datadog agent crashes due to OutOfMemoryError with JMX. So increase it from 256
  datadog_task_memory = 512
  datadog_agent_environment_variables = [
    {
      JMX_PORT = "9095"
    },
    {
      DD_ENV = var.environment
    },
    {
      SERVICE_NAME = local.subscription_service_name
    },
    {
      CONNECTOR_TYPE = "default_sink"
    },
  ]
  environment_variables = [
    {
      Environment = var.environment
    },
    {
      SERVICE_NAME = local.subscription_service_name
    },
    {
      CONNECT_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    },
    {
      KAFKA_TOPICS = var.subscription_kafka_topic
    },
    {
      START_READING_RECORDS_FROM = var.start_reading_records_from
    },
    {
      CONNECTOR_NAME = local.subscription_service_name
    },
    {
      CONNECT_KEY_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      CONNECT_VALUE_CONVERTER = "org.apache.kafka.connect.storage.StringConverter"
    },
    {
      SECRETS_MANAGER_SF_CREDS = "sforce_subscription_preference_creds"
    },
    {
      SOBJECT_NAME = "Subscription_History__c"
    },
    {
      SOBJECT_ID_NAME = "Id"
    },
    {
      SOBJECT_OPERATION = "createSObject"
    },
    {
      SF_INSTANCE = var.salesforce_login_url
    },
    {
      DLQ_TOPIC_NAME = var.subscription_dlq_topic_name
    },
    {
      DLQ_HEADERS_ENABLE = "true"
    },
    {
      DEBUG_MODE = "false"
    },
    {
      CONNECT_LOG4J_ROOT_LOGLEVEL = "ERROR"
    }
  ]
}

# This rule will allow kafka-connect tasks to communicate with each other in distributed mode
resource "aws_security_group_rule" "subscription_allow_intra_cluster_communication" {
  from_port         = 8083
  to_port           = 8083
  protocol          = "tcp"
  security_group_id = module.kafka_sforce_sink_subscription_preference_updates_fargate_environment.fargate_security_group_id
  self              = true
  type              = "ingress"
}

# This rule will allow AKHQ to communicate with this kafka-connect service (LB)
resource "aws_security_group_rule" "subscription_allow_orchard_prod_private" {
  type              = "ingress"
  from_port         = 443
  to_port           = 443
  protocol          = "TCP"
  security_group_id = module.kafka_sforce_sink_subscription_preference_updates_fargate_environment.fargate_load_balancer_security_group_id
  prefix_list_ids = [
    data.aws_ec2_managed_prefix_list.orchard_prod_private.id
  ]
  depends_on = [module.kafka_sforce_sink_subscription_preference_updates_fargate_environment]
}

module "subscription_fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/kafka_connector?ref=6.16.1"

  environment        = var.environment
  application_family = var.application_family
  additional_tags    = var.additional_tags
  teams              = ["kdh", "fansifter"]
  environment_type   = "fargate"
  service_name       = local.subscription_service_name
  connector_type     = "default_sink"

  notification_endpoints            = var.notification_endpoints
  escalation_notification_endpoints = var.notification_endpoints

  monitor_kafka_topics_cluster_name = "${var.environment}-${var.msk_cluster_name}"
  monitor_kafka_topics              = [var.subscription_kafka_topic]
  dlq_topic_name                    = var.subscription_dlq_topic_name

  healthy_tasks_monitor_enabled   = true
  service_cpu_monitor_enabled     = true
  error_monitor_enabled           = true
  healthy_tasks_evaluation_window = "last_15m"
  service_cpu_time_window         = "last_15m"
}