module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/lambda-audience/automated-emails-sender/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_elasticache_replication_group" "ows_email_campaigns_redis_cache" {
  replication_group_id = "${var.environment}-ows-email-campaigns"
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

module "lambda" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=5.3.0"
  lambda_name        = var.lambda_name
  lambda_description = "Lambda for continuous sending of automated emails via Sendgrid"
  environment        = var.environment
  application_family = var.application_family

  lambda_function_timeout                        = var.lambda_timeout
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_reserved_concurrency

  lambda_function_environment_variables = {
    ENVIRONMENT                          = var.environment
    SENTRY_DSN                           = module.sentry.sentry_key_dsn_public_output
    LAMBDA_TIMEOUT                       = var.lambda_timeout
    SNOWFLAKE_ACCOUNT                    = var.snowflake_account
    SNOWFLAKE_DATABASE                   = var.snowflake_database
    SNOWFLAKE_SCHEMA                     = var.snowflake_schema
    SNOWFLAKE_WAREHOUSE                  = var.snowflake_warehouse
    SNOWFLAKE_ROLE                       = var.snowflake_role
    SNOWFLAKE_USER                       = var.snowflake_user
    SNOWFLAKE_PRIVATE_KEY_SECRET_NAME    = local.snowflake_private_key_secret_name
    SNOWFLAKE_KEY_PASSPHRASE_SECRET_NAME = local.snowflake_key_passphrase_secret_name
    REDIS_HOST                           = data.aws_elasticache_replication_group.ows_email_campaigns_redis_cache.primary_endpoint_address
    STRIPO_BASE_URL                      = var.stripo_base_url
    STRIPO_CLIENT_ID                     = var.stripo_client_id
    PREFERENCE_CENTER_URL                = var.preference_center_url
    PREFERENCE_CENTER_SECRET_KEY_NAME    = local.preference_center_secret_key_name
    UNSUBSCRIBE_HOST                     = var.unsubscribe_host
    SENDGRID_SME_API_KEY_SECRET_NAME     = local.sendgrid_sme_api_key_secret_name
    SENDGRID_ORCHARD_API_KEY_SECRET_NAME = local.sendgrid_orchard_api_key_secret_name
    SENDGRID_AWAL_API_KEY_SECRET_NAME    = local.sendgrid_awal_api_key_secret_name
    STRIPO_CLIENT_SECRET_NAME            = local.stripo_client_secret_name
    REPLY_TO_SECRET_KEY_NAME             = local.reply_to_secret_key_name
    REPLY_TO_SME_DOMAIN                  = var.reply_to_domains["sme"]
    REPLY_TO_ORCHARD_DOMAIN              = var.reply_to_domains["theorchard"]
    REPLY_TO_AWAL_DOMAIN                 = var.reply_to_domains["awal"]
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_extra_read_policy.arn,
    data.aws_iam_policy.refresh_m2m_token_read_policy.arn,
    module.automated_emails_s3_bucket.s3_read_only_policy_arn_output,
  ]

  use_container_image = true

  datadog_advanced_enabled = true

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids
}

resource "aws_lambda_function_event_invoke_config" "lambda_event_invoke_config" {
  function_name          = module.lambda.lambda_arn
  maximum_retry_attempts = 2

  destination_config {
    on_failure {
      destination = module.lambda.lambda_dlq_arn
    }
  }
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.18.2"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}