provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/lambda-audience/email-campaigns-dispatcher/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_iam_policy" "refresh_m2m_token_read_policy" {
  name = "SecretsManager-${var.environment}-refresh-m2m-token-read-policy"
}

data "aws_elasticache_replication_group" "ows_email_campaigns_redis_cache" {
  replication_group_id = "${var.environment}-ows-email-campaigns"
}

module "lambda" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"
  lambda_name        = var.lambda_name
  lambda_description = "Lambda for dispatching jobs to send email campaigns"
  environment        = var.environment
  application_family = var.application_family

  lambda_function_timeout                        = var.lambda_timeout
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_reserved_concurrency

  lambda_function_environment_variables = {
    ENVIRONMENT                          = var.environment
    SENTRY_DSN                           = module.sentry.sentry_key_dsn_public_output
    SNOWFLAKE_ACCOUNT                    = var.snowflake_account
    SNOWFLAKE_DATABASE                   = var.snowflake_database
    SNOWFLAKE_SCHEMA                     = var.snowflake_schema
    SNOWFLAKE_WAREHOUSE                  = var.snowflake_warehouse
    SNOWFLAKE_ROLE                       = var.snowflake_role
    SNOWFLAKE_USER                       = var.snowflake_user
    QUOTA_STRATEGY                       = var.quota_strategy
    SNOWFLAKE_PRIVATE_KEY_SECRET_NAME    = local.snowflake_private_key_secret_name
    SNOWFLAKE_KEY_PASSPHRASE_SECRET_NAME = local.snowflake_key_passphrase_secret_name
    REDIS_HOST                           = data.aws_elasticache_replication_group.ows_email_campaigns_redis_cache.primary_endpoint_address
  }

  iam_managed_policy_attachments = [
    data.aws_iam_policy.refresh_m2m_token_read_policy.arn,
    aws_iam_policy.sender_lambda_invoke_policy.arn,
  ]

  cloudwatch_event_enabled  = true
  cloudwatch_event_schedule = "rate(1 minute)"

  use_container_image = true

  datadog_advanced_enabled = true

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.6"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}