module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/lambda-audience/sendgrid-webhooks/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_caller_identity" "current" {}

data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

module "lambda_audience_sendgrid_webhooks" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=4.3.0"
  lambda_name        = var.lambda_name
  lambda_description = "Lambda to process Sendgrid Webhook events"
  environment        = var.environment
  application_family = var.application_family

  lambda_function_timeout                        = var.lambda_timeout
  lambda_function_memory_size                    = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions = var.lambda_reserved_concurrency

  lambda_function_environment_variables = {
    ENVIRONMENT             = var.environment
    SENTRY_DSN              = module.sentry.sentry_key_dsn_public_output
    KAFKA_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    SENDGRID_PUBLIC_KEYS    = jsonencode(var.sendgrid_public_keys)
    FAILED_EVENTS_S3_BUCKET = module.sendgrid_webhooks_s3_bucket.s3_bucket_name_output
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.files_upload_s3_policy.arn,
  ]

  use_container_image = true

  datadog_advanced_enabled = true

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment, var.application_family]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.9"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}