provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/lambda-audience/songwhip-event-processor/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=1.0.0"

  environment = var.environment
}

data "aws_elasticache_replication_group" "ows_preference_center_redis" {
  replication_group_id = "${var.environment}-ows-preference-center"
}

data "aws_iam_policy" "refresh_m2m_token_read_policy" {
  name = "SecretsManager-${var.environment}-refresh-m2m-token-read-policy"
}

data "aws_msk_cluster" "kafka_fansifter" {
  cluster_name = "${var.environment}-${var.msk_cluster_name}"
}

module "lambda" {
  source                  = "git@github.com:theorchard/terraform-lambda.git//?ref=3.1.4"
  lambda_name             = var.lambda_name
  lambda_description      = "Lambda to process Songwhip events from Amazon MSK service"
  lambda_function_timeout = 14 * 60
  environment             = var.environment
  application_family      = var.application_family

  lambda_function_memory_size = 1024

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids

  use_container_image = true

  datadog_advanced_enabled = true

  lambda_function_environment_variables = {
    ENVIRONMENT             = var.environment
    SENTRY_DSN              = module.sentry.sentry_key_dsn_public_output
    REDIS_HOST              = data.aws_elasticache_replication_group.ows_preference_center_redis.primary_endpoint_address
    KAFKA_BOOTSTRAP_SERVERS = data.aws_msk_cluster.kafka_fansifter.bootstrap_brokers_tls
    M2M_IDENTITY_ID         = var.m2m_identity_id
    M2M_PROFILE_ID          = var.m2m_profile_id
    M2M_PROFILE_TYPE        = var.m2m_profile_type
    KMS_KEY_ARN             = var.orchard_dmp_kms_key_arn
  }

  msk_event_enabled                     = true
  event_source_mapping_msk_cluster_name = "${var.environment}-${var.msk_cluster_name}"
  event_source_mapping_msk_cluster_uuid = var.msk_cluster_uuid
  event_source_mapping_batch_size       = var.msk_event_source_mapping_batch_size
  event_source_mapping_batch_window     = var.msk_event_source_mapping_batch_window
  msk_topics = [
    "event.songwhip.presave.raw"
  ]

  iam_managed_policy_attachments = [
    aws_iam_policy.kms_decrypt.arn,
    data.aws_iam_policy.refresh_m2m_token_read_policy.arn,
  ]
}

data "aws_iam_policy_document" "kms_decrypt" {
  statement {
    effect    = "Allow"
    actions   = ["kms:Decrypt", "kms:DescribeKey"]
    resources = [var.orchard_dmp_kms_key_arn]
  }
}

resource "aws_iam_policy" "kms_decrypt" {
  name        = "${var.environment}-${var.lambda_name}-kms-decrypt"
  description = "Allow Lambda to decrypt fan/presave data encrypted by songwhip-api"
  policy      = data.aws_iam_policy_document.kms_decrypt.json
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=5.0.0"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.18.2"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}