provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/lambda-audience/twilio-webhooks-inbound/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

data "aws_caller_identity" "current" {}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.lambda_name
  secret_name        = each.value
}

module "lambda_audience_twilio_webhooks_inbound" {
  source             = "git@github.com:theorchard/terraform-lambda.git//?ref=4.2.0"
  lambda_name        = var.lambda_name
  lambda_description = "Lambda to process Twilio Webhook inbound events"
  environment        = var.environment
  application_family = var.application_family

  lambda_function_timeout                           = var.lambda_timeout
  lambda_function_memory_size                       = var.lambda_memory_size
  lambda_function_reserved_concurrent_executions    = var.lambda_reserved_concurrency
  lambda_function_provisioned_concurrent_executions = var.lambda_function_min_provisioned_concurrency

  lambda_function_environment_variables = {
    ENVIRONMENT                         = var.environment
    SENTRY_DSN                          = module.sentry.sentry_key_dsn_public_output
    KMS_KEY_ID                          = data.aws_kms_alias.kms_alias.name
    POSTGRES_HOST                       = var.postgres_host
    POSTGRES_PORT                       = var.postgres_port
    POSTGRES_NAME                       = var.postgres_name
    POSTGRES_USERNAME                   = var.postgres_username
    POSTGRES_PASSWORD_SECRET_NAME       = local.postgres_password_secret_name
  }

  iam_managed_policy_attachments = [
    aws_iam_policy.kms_policy.arn,
    data.aws_iam_policy.refresh_m2m_token_read_policy.arn,
  ]

  use_container_image = true

  datadog_advanced_enabled = true

  vpc_enabled    = true
  vpc_id         = module.vpc_info.vpc_id
  vpc_subnet_ids = module.vpc_info.default_private_subnet_ids
}


resource "aws_appautoscaling_target" "lambda_pc_target" {
  max_capacity       = var.lambda_function_max_provisioned_concurrency
  min_capacity       = var.lambda_function_min_provisioned_concurrency
  resource_id        = "function:${module.lambda_audience_twilio_webhooks_inbound.lambda_name}:${module.lambda_audience_twilio_webhooks_inbound.lambda_qualifier}"
  scalable_dimension = "lambda:function:ProvisionedConcurrency"
  service_namespace  = "lambda"
}

resource "aws_appautoscaling_policy" "lambda_pc_policy" {
  name               = "${var.environment}-${var.service_name}-lambda-scale-up-policy"
  policy_type        = "TargetTrackingScaling"
  resource_id        = aws_appautoscaling_target.lambda_pc_target.resource_id
  scalable_dimension = aws_appautoscaling_target.lambda_pc_target.scalable_dimension
  service_namespace  = aws_appautoscaling_target.lambda_pc_target.service_namespace

  target_tracking_scaling_policy_configuration {
    target_value       = 0.7
    predefined_metric_specification {
      predefined_metric_type = "LambdaProvisionedConcurrencyUtilization"
    }
    scale_out_cooldown  = 30
    scale_in_cooldown   = 30
  }
}

module "sentry" {
  source             = "git@github.com:theorchard/terraform-sentry.git//?ref=4.1.2"
  service_name       = var.lambda_name
  environment        = var.environment
  application_family = var.application_family
  teams              = [var.environment]
  platform           = "python"
}

module "datadog" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/lambda?ref=6.13.7"

  environment                       = var.environment
  service_name                      = var.lambda_name
  teams                             = ["fansifter"]
  lambda_invocation_monitor_enabled = false

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}