module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.application_family
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "qa-fansifter-terraform-state"
    key     = "qa/ows-email-campaigns/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "${var.environment}-fansifter.theorchard.io"
}

data "aws_route53_zone" "route53_zone_networking" {
  provider = aws.networking
  name     = "theorchard.io."
}

module "custom_waf" {
  source       = "git@github.com:theorchard/terraform-aws-waf.git//?ref=2.0.2"
  environment  = var.environment
  service_name = var.service_name
  aws_region   = var.aws_region

  count_waf_enabled = false
  block_waf_enabled = true
  excluded_rules = [
    "SizeRestrictions_BODY",
    "CrossSiteScripting_BODY",
    "SizeRestrictions_QUERYSTRING",
  ]
}

module "ows_service_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.8.0"

  providers = {
    aws.dns = aws.networking
  }

  environment        = var.environment
  service_name       = var.service_name
  aws_region         = var.aws_region
  application_family = var.application_family

  desired_task_count                = 2
  minimum_capacity                  = 2
  maximum_capacity                  = 4
  task_cpu                          = 1024
  task_memory                       = 2048
  health_check_grace_period_seconds = 180
  route53_zone_id                   = data.aws_route53_zone.route53_zone.zone_id
  vpc_id                            = module.vpc_info.vpc_id
  fargate_service_subnets           = module.vpc_info.default_private_subnet_ids
  load_balancer_subnets             = module.vpc_info.default_private_subnet_ids
  custom_waf_arn                    = module.custom_waf.waf_blocking_arn_output
  https_listener_allow_prefix_list_names = [
    "prod-orcd-private-subnet-prefix-list",
  ]

  splitio_enabled                = true
  ows_machine_to_machine_enabled = false

  additional_lb_target_group_arns = [
    aws_lb_target_group.email_campaigns_public_tg.arn
  ]

  iam_managed_policy_attachments = [
    aws_iam_policy.secrets_manager_extra_read_policy.arn,
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      SENTRY_DSN = module.sentry.sentry_key_dsn_public_output
    },
    {
      REDIS_HOST = module.redis_elasticache.redis_primary_endpoint_address
    },
    {
      POSTGRES_HOST = var.postgres_host
    },
    {
      POSTGRES_PORT = var.postgres_port
    },
    {
      POSTGRES_NAME = var.postgres_name
    },
    {
      POSTGRES_USER = var.postgres_username
    },
    {
      SNOWFLAKE_ACCOUNT = var.snowflake_account
    },
    {
      SNOWFLAKE_DATABASE = var.snowflake_database
    },
    {
      SNOWFLAKE_SCHEMA = var.snowflake_schema
    },
    {
      SNOWFLAKE_WAREHOUSE = var.snowflake_warehouse
    },
    {
      SNOWFLAKE_ROLE = var.snowflake_role
    },
    {
      SNOWFLAKE_USER = var.snowflake_user
    },
    {
      STRIPO_BASE_URL = var.stripo_base_url
    },
    {
      STRIPO_CLIENT_ID = var.stripo_client_id
    },
    {
      STRIPO_AUTOMATED_CLIENT_ID = var.stripo_automated_client_id
    },
    {
      STRIPO_AUTOSAVE_USERNAME = var.stripo_autosave_username
    },
    {
      STRIPO_V2_BASE_URL = var.stripo_v2_base_url
    },
    {
      STRIPO_V2_COEDITING_URL = var.stripo_v2_coediting_url
    },
    {
      STRIPO_V2_CLIENT_ID = var.stripo_v2_client_id
    },
    {
      STRIPO_V2_AUTOMATED_CLIENT_ID = var.stripo_v2_automated_client_id
    },
    {
      PREFERENCE_CENTER_URL = var.preference_center_url
    },
    {
      UNSUBSCRIBE_HOST = var.unsubscribe_host
    },
    {
      PREFERENCE_CENTER_SECRET_KEY_NAME = local.preference_center_secret_key_name
    },
    {
      EMAIL_PUBLIC_PREVIEW_TTL_SECONDS = 604800 # 7 days
    },
    {
      REPLY_TO_SME_DOMAIN = var.reply_to_domains["sme"]
    },
    {
      REPLY_TO_ORCHARD_DOMAIN = var.reply_to_domains["theorchard"]
    },
    {
      REPLY_TO_AWAL_DOMAIN = var.reply_to_domains["awal"]
    },
  ]

  secrets = [
    {
      POSTGRES_PASSWORD = "${var.environment}/${var.service_name}/RDS_EMAIL_CAMPAIGNS_PASSWORD"
    },
    {
      SNOWFLAKE_PRIVATE_KEY = "${var.environment}/${var.service_name}/SNOWFLAKE_PRIVATE_KEY"
    },
    {
      SNOWFLAKE_KEY_PASSPHRASE = "${var.environment}/${var.service_name}/SNOWFLAKE_KEY_PASSPHRASE"
    },
    {
      SENDGRID_SME_API_KEY = "${var.environment}/${var.service_name}/SENDGRID_API_KEY"
    },
    {
      SENDGRID_ORCHARD_API_KEY = "${var.environment}/${var.service_name}/SENDGRID_API_KEY"
    },
    {
      SENDGRID_AWAL_API_KEY = "${var.environment}/${var.service_name}/SENDGRID_API_KEY"
    },
    {
      STRIPO_CLIENT_SECRET = "${var.environment}/${var.service_name}/STRIPO_CLIENT_SECRET"
    },
    {
      STRIPO_AUTOMATED_CLIENT_SECRET = "${var.environment}/${var.service_name}/STRIPO_AUTOMATED_CLIENT_SECRET"
    },
    {
      STRIPO_AUTOSAVE_PASSWORD = "${var.environment}/${var.service_name}/STRIPO_AUTOSAVE_PASSWORD"
    },
    {
      STRIPO_V2_CLIENT_SECRET = "${var.environment}/${var.service_name}/STRIPO_V2_CLIENT_SECRET"
    },
    {
      STRIPO_V2_AUTOMATED_CLIENT_SECRET = "${var.environment}/${var.service_name}/STRIPO_V2_AUTOMATED_CLIENT_SECRET"
    },
    {
      SPLIT_IO_API_KEY = "${var.environment}/split/API_KEY"
    },
    {
      EMAIL_PUBLIC_PREVIEW_SECRET_KEY = "${var.environment}/${var.service_name}/EMAIL_PUBLIC_PREVIEW_SECRET_KEY"
    },
    {
      REPLY_TO_SECRET_KEY = "${var.environment}/${var.service_name}/REPLY_TO_SECRET_KEY"
    },
    {
      GOOGLE_FONTS_API_KEY = "${var.environment}/${var.service_name}/GOOGLE_FONTS_API_KEY"
    },
  ]
}

module "fargate_service_dashboard" {
  source = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=6.13.7"

  environment        = var.environment
  environment_type   = "fargate"
  service_name       = var.service_name
  application_family = var.application_family
  teams              = [var.application_family]

  service_4xx_monitor_enabled = false

  service_cpu_monitor_evaluation_function = "avg"
  service_cpu_time_window                 = "last_10m"

  notification_endpoints            = "@slack-fansifter-alerts"
  escalation_notification_endpoints = "@slack-fansifter"
}

module "sentry" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=4.1.2"

  environment        = var.environment
  platform           = "python"
  service_name       = var.service_name
  application_family = var.application_family
}

module "redis_elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws
  }

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name

  vpc_id          = module.vpc_info.vpc_id
  route53_zone_id = data.aws_route53_zone.route53_zone.id

  cache_engine               = "redis"
  redis_engine_version       = "7.0"
  cache_parameter_group_name = "default.redis7"
  cache_node_type            = "cache.t4g.small"
  cache_node_count           = 1
  cache_subnet_group_name    = "${var.environment}-elasticache-subnet-group"
}

module "secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  application_family = var.application_family
  environment        = var.environment
  service_name       = var.service_name
  secret_name        = each.value
}