# IAM role with write-only access to the fansifter-text-campaign-assets bucket

## IAM Assume Role Policy to allow ows-text-campaigns and Fansifter engineers to assume policy
## to generate credentials for file upload into the bucket
data "aws_iam_policy_document" "browser_upload_role_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "AWS"
      identifiers = [
        module.ows_service_fargate_environment.fargate_task_iam_role_arn,
        "arn:aws:iam::${data.aws_caller_identity.current.account_id}:role/fansifter-role",
      ]
    }
  }
}

resource "aws_iam_role" "browser_upload_role" {
  name                 = "${var.environment}-${var.service_name}-browser-upload-role"
  max_session_duration = 3600
  assume_role_policy   = data.aws_iam_policy_document.browser_upload_role_assume_role_policy_document.json
}

## Attaching bucket write-only access policy to the browser upload role
resource "aws_iam_role_policy_attachment" "browser_upload_policy_attachment" {
  role       = aws_iam_role.browser_upload_role.id
  policy_arn = aws_iam_policy.assets_s3_wo_policy.arn
}

## IAM policy to allow ows-text-campaigns to assume the browser upload role
data "aws_iam_policy_document" "browser_upload_sts_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    resources = [
      aws_iam_role.browser_upload_role.arn
    ]
  }
}

resource "aws_iam_policy" "browser_upload_sts_policy" {
  name        = "STS-${var.environment}-${var.service_name}-browser-upload-assume-role-policy"
  description = "Policy to let ${var.service_name} assume ${aws_iam_role.browser_upload_role.name} role."
  policy      = data.aws_iam_policy_document.browser_upload_sts_policy_document.json
}