data "aws_wafv2_web_acl" "cloudfront_waf" {
  name  = "${var.environment}-fansifter-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

data "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name = "Managed-SimpleCORS"
}

resource "aws_cloudfront_origin_access_control" "assets" {
  name                              = "${var.environment}-${var.service_name}"
  description                       = "${var.environment}-${var.service_name} Policy"
  origin_access_control_origin_type = "s3"
  signing_behavior                  = "always"
  signing_protocol                  = "sigv4"
}

resource "aws_cloudfront_distribution" "assets_distribution" {
  # checkov:skip=CKV_AWS_310: Origin failover is not configured for the QA env.
  # checkov:skip=CKV2_AWS_47: Ensure AWS CloudFront attached WAFv2 WebACL is configured with AMR for Log4j Vulnerability
  # checkov:skip=CKV_AWS_374: Ensure AWS CloudFront web distribution has geo restriction enabled
  enabled             = true
  is_ipv6_enabled     = false
  comment             = "Distribution for Fansifter text-campaigns assets"
  price_class         = "PriceClass_All"
  http_version        = "http2"
  aliases             = [local.assets_cloudfront_domain]
  default_root_object = "index.html"
  web_acl_id          = data.aws_wafv2_web_acl.cloudfront_waf.arn

  origin {
    domain_name              = "${module.assets_s3_bucket.s3_bucket_name_output}.s3.amazonaws.com"
    origin_id                = "S3-${module.assets_s3_bucket.s3_bucket_name_output}"
    origin_access_control_id = aws_cloudfront_origin_access_control.assets.id
  }

  default_cache_behavior {
    viewer_protocol_policy = "https-only"
    compress               = false
    allowed_methods        = ["GET", "HEAD", "OPTIONS"]
    cached_methods         = ["GET", "HEAD"]

    response_headers_policy_id = data.aws_cloudfront_response_headers_policy.response_headers_policy.id

    target_origin_id = "S3-${module.assets_s3_bucket.s3_bucket_name_output}"
    min_ttl          = 0
    default_ttl      = 86400
    max_ttl          = 31536000

    forwarded_values {
      query_string = false

      cookies {
        forward = "none"
      }
      headers = [
        "Origin",
        "Access-Control-Request-Headers",
        "Access-Control-Request-Method",
      ]
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  logging_config {
    include_cookies = false
    bucket          = local.cloudfront_logs_bucket
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = "TLSv1.2_2021"
  }
}

resource "aws_route53_record" "assets_route53_record" {
  name    = var.assets_cloudfront_subdomain
  zone_id = data.aws_route53_zone.route53_zone.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.assets_distribution.domain_name]
}